In VBA is it possible to get the value of a button on a worksheet which is stored as a variable?

In VBA is there a way to refer to a button on a worksheet that's held as a variable? Unless I refer to the sheet directly it seems to throw a compile error for "Method or data member not found". So for example:

Sub Test_Parent
    Call Test_Child(Temp_WS:=Sheet1)
End Sub

Sub Test_Child(ByVal Temp_WS as Worksheet)
    debug.print Temp_WS.Example_Button.Value
End Sub

The above triggers the error on the debug.print line. Whereas the following works without issue:

Sub Test2
    debug.print Sheet1.Example_Button.Value
End Sub

My gut says that this is because in the second case the compiler looks at a direct reference (e.g. Sheet1) and can see that the button exists as a member, whereas in the first case it looks at the variable and views it as a generic worksheet type (rather than being Sheet1) and so doesn't think there would be this member? Or maybe I'm completely off the mark?

Either way, is there a way around it? (Or am I doing something stupid for that matter?) If not it's not the end of the world, but I typically like to minimise the number of hard-coded references to sheets so if this is a way to resolve it then that would be great.

Example_Button, as an ActiveX OLEObject is a member of Sheet1 and it can be referenced as Sheet1.Example_Button.

But it is also an OLEObject and a shape, too.

You cannot find it as a member of the general Worksheet object. You can use the Sub as you try, generally declaring the parameter As Variant (or As Object), passing the Sheet1 class itself:

Sub Test_Child(ByVal Temp_WS as Variant)
    Debug.Print Temp_WS.Example_Button.Value
End Sub

And this will work. Practically, declaring As Variant or As Object it simulates the next Sub, which allows declaring he parameter as the involved sheet class. The single one exposing the object in the way you try:

Sub Test_ChildSheetSh1(ByVal Temp_WS As Sheet1)
    Debug.Print Temp_WS.Example_Button.Value
End Sub

But better approaches are to use the object as OLEObject or as shape, which works for Worksheet object, too:

Sub Test_ChildOLE(ByVal Temp_WS as Worksheet)
    Debug.Print Temp_WS.OLEObjects("Example_Button").Object.Value
End Sub

or

Sub Test_ChildSh(ByVal Temp_WS As Worksheet)
    Debug.Print Temp_WS.Shapes("Example_Button").OLEFormat.Object.Object.Value
End Sub

You can event use Worksheet for a Form type button (not an ActiveX) in the next way:

Sub Test_ChildForm(ByVal Temp_WS As Worksheet)
    Debug.Print Temp_WS.Shapes("Example_Button").OLEFormat.Object.Caption
End Sub