Data moving not following vba script

This is what I am looking for in the script

Get the information of the raw data sheet distributed over the different spreadsheets if value in column J matches name of the spreadsheet. If value in column J matches the spreadsheet name the row can be cut to that spreadsheet in the first available row (several rows will end up in each spreadsheet). Dont move the data from raw data spreadsheet if no exact match is found (should stay in raw data file)

Furthermore it should check for duplicates based on value in column B (is a unique number. If that number already exist in the spreadsheet where it is moved to than skip that line. The line can be deleted from raw data without cutting in that case.

What is the problem: If it finds a value in column J in cannot match it still puts in in a spreadsheet (so a spreadsheet with a not matching name) printscreen (see columnJ). Cannot see what is wrong?

Sub DistributeData()
    Dim rawDataSheet As Worksheet
    Dim targetSheet As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim valueToMatch As String
    Dim uniqueNumber As String
    Dim targetRow As Long
    Dim duplicateFound As Boolean

    Application.ScreenUpdating = False ' Disable screen updating for better performance
    Application.Calculation = xlCalculationManual ' Disable automatic calculations

    Set rawDataSheet = ThisWorkbook.Worksheets("RawData") ' Replace "RawData" with the name of your raw data sheet

    With rawDataSheet
        lastRow = .Cells(.Rows.Count, "J").End(xlUp).Row

        For i = 2 to lastRow Step 1 ' Loop through the rows
            valueToMatch = .Cells(i, "J").Value
            uniqueNumber = .Cells(i, "B").Value
            duplicateFound = False

            On Error Resume Next
            Set targetSheet = ThisWorkbook.Worksheets(valueToMatch)
            On Error GoTo 0

            If Not targetSheet Is Nothing Then ' If a matching sheet is found
                For targetRow = 2 To targetSheet.Cells(targetSheet.Rows.Count, "J").End(xlUp).Row
                    If targetSheet.Cells(targetRow, "B").Value = uniqueNumber Then
                        duplicateFound = True
                        Exit For
                    End If
                Next targetRow

                If Not duplicateFound Then
                    ' Cut the row to the target sheet
                    .Rows(i).Copy
                    targetSheet.Cells(targetSheet.Cells(targetSheet.Rows.Count, "J").End(xlUp).Row + 1, 1).PasteSpecial xlPasteValues
                    .Rows(i).Delete
                Else
                    ' Delete the row from the raw data sheet
                    .Rows(i).Delete
                End If
            End If
        Next i

        .UsedRange.Columns("E").NumberFormat = "General" ' Set column E format to General for numbers
        .UsedRange.Font.ColorIndex = xlAutomatic ' Reset font color to automatic
        .UsedRange.Interior.ColorIndex = xlNone ' Reset background color to none
    End With

    Application.ScreenUpdating = True ' Enable screen updating
    Application.Calculation = xlCalculationAutomatic ' Enable automatic calculations
End Sub

 On Error Resume Next
            Set targetSheet = ThisWorkbook.Worksheets(valueToMatch)
            On Error GoTo 0

Is this coding incorrect and does it still move the line? I dont know what else to pu

Thank you in advance

The reason is rather simple. Your idea of using the following snippet

On Error Resume Next 
Set targetSheet = ThisWorkbook.Worksheets(valueToMatch) 
On Error GoTo 0

is okay. However, if there is no sheet ThisWorkbook.Worksheets(valueToMatch) (so the statement produces a runtime error that is ignored), the variable targetSheet is not modified, it keeps its value.

If the variable was not used before, it will still be Nothing, however, if it was already holding a reference to a sheet from an earlier iteration, it will keep this reference and the following code will copy the row to the previous sheet.

All you have to do is to initialize the variable at every iteration:

On Error Resume Next 
Set targetSheet = Nothing
Set targetSheet = ThisWorkbook.Worksheets(valueToMatch) 
On Error GoTo 0

Edit: Didn't saw that you are deleting rows. Of course freeflow and DavesExcel are right in the comments: You need to loop backwards.

For i = lastRow to 2 Step -1   ' Loop backwards through the rows

If this is not okay (because it would add rows in the destination sheets in reverted order), loop twice. In the first loop (from 2 to lastRow), copy the data and mark all rows that are to be deleted (eg by writing "DELETE" in col A). Then in the second loop (from lastRow to 2 step -1), delete those rows.