Excel Filter Function Include Different Array for Filtering

I wanted to make a filter function, but the array for criteria is referring to a different cell

Here is an example

My array is C3:C17, I wanted to filter the names on this array based on the list from A3:A5
Here I tried using this formula

=FILTER(HSTACK($C$3:$D$17),C3:C17=A3:A17)

I am expecting to return Agent 1, 5 and 10 with their corresponding Leaders on cell F3 but instead the formula only return 1 result which is Agent 1 and Leader 1

Expecting/Desired result

Using ISNUMBER and XMATCH:

=FILTER(C3:D17,ISNUMBER(XMATCH(C3:C17,A3:A5)))

Another alternative: BigBen Sir was pretty quick otherwise I would have opted for ISNUMBER() with XMATCH()

• Formula used in cell F3

=FILTER(C3:D17,MMULT(N(C3:C17=TOROW(A3:A5)),SEQUENCE(ROWS(A3:A5))))

To avoid additional changes in the roster, this will work using TOROW() & DROP() function: -> The first one is used to exclude the blanks while the latter is used to exclude the top 2 rows.

• Formula used in cell F3

=LET(α,TOROW(DROP(A:A,2),1),
FILTER(C3:D17,MMULT(N(α=C3:C17),SEQUENCE(COLUMNS(α)))))

Filter Using INDEX/XMATCH

• Note that this simplification only works if you want to return as many results as there are values in the 'lookup' column (A) i.e. if there are no duplicates in column C. Otherwise, you need to use FILTER and switch the XMATCH parameters i.e. do something like BigBen did in his answer.
• Note that you don't need the variables l, s, dr, and dc i.e. you can write all of it in one long line. They are used just to better understand what's going on i.e. to make it more readable.

=LET(lrg,A3:A17,srg,C3:D17,sc,1,
    l,TOCOL(lrg,3),s,INDEX(srg,,sc),
    dr,XMATCH(l,s),dc,SEQUENCE(,COLUMNS(srg)),
IFERROR(INDEX(srg,dr,dc),""))

Another alternative:

Formula in F3:

=FILTER(C3:D17,COUNTIF(A3:A5,C3:C17))

Or simply (but slow):

=FILTER(C:D,COUNTIF(A3:A5,C:C))