Cannot loop Pivot Chart ShowAllFieldButtons on Multiple Sheets

I have a scenario where I need to hide the Field Buttons on a Pivot Chart. I need to loop through a series of sheets, and do this to each chart on each sheet.

I know I'm missing something simple - but I'm having trouble looping it through.

Sub DivisionMacro()
    
    Dim ws As Worksheet
    Dim ch As ChartObject
    
    'Create Division Sheets
    ActiveSheet.PivotTables("PivotTable12").ShowPages PageField:= _
                                                      "User Custom Fields.Division2023"
    
    'UnProtect Sheet
    Cells.Select
    ActiveSheet.Unprotect
    
    'Loop Through
    For Each ws In ActiveWorkbook.Worksheets
        'Hide Top Row
        ws.Rows(1).Hidden = True
        'Create Chart
        ws.Shapes.AddChart2(216, xlBarClustered).Select
        'Show Chart Field Buttons
        ws.ChartObjects("Chart 1").Activate
        ActiveChart.ShowAllFieldButtons = False
        
        'Protect Sheet
        'ws.Protect Password:=strPassword, DrawingObjects:=True, Contents:=True, Scenarios:=True, _
        'UserInterfaceOnly:=True, AllowFormattingCells:=False, AllowFormattingColumns:=True, _
        'AllowFormattingRows:=False, AllowInsertingColumns:=False, AllowInsertingRows:=False, _
        'AllowInsertingHyperlinks:=False, AllowDeletingColumns:=False, AllowDeletingRows:=False, _
        'AllowSorting:=False, AllowFiltering:=False, AllowUsingPivotTables:=True
        
    Next ws
    
End Sub

First, there's no need to do any selecting or activating. Secondly, when creating the chart, assign the object to a variable, and then use that variable to set your settings. Here's an example...

Dim ws As Worksheet
Dim pt As PivotTable
Dim shp As Shape

For Each ws In ActiveWorkbook.Worksheets
    On Error Resume Next
    Set pt = ws.PivotTables(1)
    On Error GoTo 0
    If Not pt Is Nothing Then
        Set shp = ws.Shapes.AddChart2(216, xlBarClustered)
        With shp.Chart
            .SetSourceData pt.TableRange2
            .ShowAllFieldButtons = False
        End With
        Set pt = Nothing
    End If
Next ws

Note that as it loops through each worksheet, it first checks whether a pivot table exists. If so, then it proceeds to create the chart, etc.