Modifying text using Word VBA

I have the following working script which extract the text from a Word file:

Sub GetTextFromWord()
    Dim fso As FileSystemObject
    Dim oWd As Object, oDoc As Object
    Const wdFormatText as Long = 2, wdCRLF as Long = 0

    Set fso = New FileSystemObject
    Set oWd = CreateObject("word.application")

    Set oDoc = oWd.Documents.Open("C:\temp\PDFs\New folder\Test")

    Dim filePath As String: filePath = "C:\temp\PDFs\New folder\Test" & "TEST" & ".txt"  'filename
    Debug.Print filePath
    
    oDoc.SaveAs2 fileName:=filePath, _
        FileFormat:=wdFormatText, LockComments:=False, Password:="", _
        AddToRecentFiles:=True, WritePassword:="", ReadOnlyRecommended:=False, _
        EmbedTrueTypeFonts:=False, SaveNativePictureFormat:=False, SaveFormsData _
        :=False, SaveAsAOCELetter:=False, Encoding:=1252, InsertLineBreaks:=False _
        , AllowSubstitutions:=True, LineEnding:=wdCRLF, CompatibilityMode:=0
        
    oDoc.Close False
    oWd.Quit
End Sub

I wish to modify this so that for every instance of Bold text in the file this is replaced with "HEADING:" original text...

Attempt so Far:

Sub GetTextFromWord()
    Dim fso As FileSystemObject
    Dim oWd As Object, oDoc As Object
    Const wdFormatText As Long = 2, wdCRLF As Long = 0

    Set fso = New FileSystemObject
    Set oWd = CreateObject("word.application")

    Set oDoc = oWd.Documents.Open("C:\temp\PDFs\New folder\Test")

    Dim filePath As String: filePath = "C:\temp\PDFs\New folder\" & "TEST" & ".txt"  'filename
    Debug.Print filePath
    
    With oDoc.Content.Find
 .ClearFormatting
 .Font.Bold = True
 .Execute FindText:="", ReplaceWith:="HEADER: ^&", _
 Format:=True, Replace:=wdReplaceAll
End With
    
    oDoc.SaveAs2 Filename:=filePath, _
        FileFormat:=wdFormatText, LockComments:=False, Password:="", _
        AddToRecentFiles:=True, WritePassword:="", ReadOnlyRecommended:=False, _
        EmbedTrueTypeFonts:=False, SaveNativePictureFormat:=False, SaveFormsData _
        :=False, SaveAsAOCELetter:=False, Encoding:=1252, InsertLineBreaks:=False _
        , AllowSubstitutions:=True, LineEnding:=wdCRLF, CompatibilityMode:=0
        
    oDoc.Close False
    oWd.Quit
End Sub

This generates the TEST file and shows no error but checking the file the changes have not been made.

Tested in Word:

Sub Tester()
    Dim doc As Object
    
    Set doc = ActiveDocument
    PrependBoldText doc, "HEADER: "

End Sub


Sub PrependBoldText(doc As Object, prefix As String)
    Dim rng As Object
    Set rng = doc.Content
    With rng.Find
        .ClearFormatting
        .Format = True
        .Font.Bold = True
        .Wrap = 0 'wdFindStop
        Do While .Execute
            'rng is now the range for the found text...
            rng.Text = prefix & rng.Text
        Loop
    End With
End Sub