Need fix for runtime error 1004 in VBA_script

I try to get my hands on VBA-scripts and wrote a script that results in a runtime error 1004

I wrote a script that should do the following:

• check number of substring in each cell in column A; sheets DATA, whereby substrings are seperated by ";"
• if n>1: copy the row n-times below the respective cell; where n is number of substring in a cell
• fill each cell with only one of the substrings

Sub CopyRowsAndFillSubstrings()
    Dim lastRow As Long
    Dim i As Long, j As Long
    Dim substrCount As Long
    Dim substrArr() As String
    
    ' Specify the sheet name
    Dim sheetName As String
    sheetName = "Sheet1"
    
    ' Define the range of data
    lastRow = Sheets(sheetName).Cells(Rows.Count, "A").End(xlUp).Row
    
    ' Loop through each row
    For i = lastRow To 1 Step -1
        substrArr = Split(Sheets(sheetName).Range("A" & i).Value, ";")
        substrCount = UBound(substrArr) - LBound(substrArr) + 1
        
        If substrCount > 1 Then
            ' Copy the row n times, where n is the number of substrings
            For j = 2 To substrCount
                Sheets(sheetName).Rows(i + 1).Insert Shift:=xlDown
                Sheets(sheetName).Rows(i).Copy Destination:=Sheets(sheetName).Rows(i + 1)
            Next j
            
            ' Fill each cell in the copied rows with one of the substrings
            For j = 0 To substrCount - 1
                Sheets(sheetName).Cells(i + j, "A").Value = substrArr(j)
            Next j
        End If
    Next i
End Sub

According to the Editor I need to debug this following line below the second "For-Block":
Sheets(sheetName).Rows(i).Copy Destination:=Sheets(sheetName).Rows(i + 1)

However, I don't see an error here.
Could anyone help?

There are two solutions depending on how you want it.

Option Explicit

Sub CopyRowsAndFillSubstrings()
    Dim lastRow As Long
    Dim i As Long, j As Long
    'Dim substrCount As Long
    Dim substrArr() As String
    
    ' Specify the sheet name
    Dim wb As Workbook
    Dim ws As Worksheet
    Set wb = ActiveWorkbook
    Set ws = wb.Worksheets("Sheet1")
    
    ' Define the range of data
    lastRow = ws.Cells(Rows.Count, "A").End(xlUp).Row
    
    ' Loop through each row
    For i = lastRow To 1 Step -1
        substrArr = Split(ws.Range("A" & i).Value, ";")
        'substrCount = UBound(substrArr) - LBound(substrArr) + 1
        'It's the same as UBound(substrArr)
        
        'Run this if you want to replace the ";" string
        If UBound(substrArr) > 0 Then
            ' Copy the row n times, where n is the number of substrings
            ws.Rows(i + 1 & ":" & i + UBound(substrArr)).Insert shift:=xlDown
            For j = 0 To UBound(substrArr)
                ws.Cells(i + j, 1) = substrArr(j)
            Next j
        End If
        
        'Or run this if you want to write them under the ";" string
'        If UBound(substrArr) > 0 Then
'            ' Copy the row n times, where n is the number of substrings
'            For j = 0 To UBound(substrArr)
'                ws.Rows(i + j + 1).Insert Shift:=xlDown
'                ws.Cells(i + j + 1, 1) = substrArr(j)
'            Next j
'        End If
    Next i
End Sub

This message is related to protected cells that you are trying to change through VBA. Suppose you protected the sheet with the command:

ASHEET.Protect Password:=YOUR_PASS, UserInterfaceOnly:=True, _
       AllowFormattingCells:=True, DrawingObjects:=False, Contents:=True

If you save the workbook, close it and then open it, YOU HAVE TO PROTECT THE SHEETS AGAIN WHEN OPENING with the same command, even when trying to modify with VBA some protected cells, you will get the error message. It's as if the setting UserInterfaceOnly:=True is not saved and you have to remind excel every time you open the book.

Private Sub Workbook_Open()
   Call protectAllSheets
End Sub

Public Sub protectAllSheets()
   Dim r As Worksheet
   For Each r In ThisWorkbook.Worksheets
      r.Protect Password:=YOUR_PASS, _
                UserInterfaceOnly:=True, _
                AllowFormattingCells:=True, _
                DrawingObjects:=False, _
                Contents:=True
   Next
End Sub