Replacing a character in awk

I am using the following command to do a manipulation on a file:

awk '{delta = $1 - avg; avg += delta / NR; mean2 += delta * ($1 - avg); } END { print avg" "sqrt(642)*sqrt(mean2 / NR); }' param_A_ratio_re_truncated.txt

Now, I want to repeat this command line at once but replace "A" in the file name with "D, G, K, M" etc. other than typing the line every time. While I can replace numerical values in a file name, I am not sure how to change a character. Any suggestions would be appreciated. Thank you.

You can try:

awk '.....' param_[ADGKM]_ratio_re_truncated.txt

... but this is going to generate a single avg/sqrt/mean output (ie, the awk script will process all files as one big set of data).

If the intention is to generate a separate avg/sqrt/mean for each file, one easy/quick solution:

for fname in param_[ADGKM]_ratio_re_truncated.txt
do
    echo "######### input: ${fname}"
    awk '.....' "${fname}"
done

You can use a single awk script to process all files and generate a separate avg/sqrt/mean for each file but it will require a bit more code, eg:

awk '
function print_output() {
    if (rowcnt > 0)
        print FILENAME, avg, sqrt(642)*sqrt(mean2 / rowcnt)
    delta = avg = mean2 = ""                          # reset variables for next file
    rowcnt = 0
}
FNR==1 { print_output() }                             # FNR==1 => new file so print results for previous file
       { rowcnt++
         delta = $1 - avg
         avg += delta / rowcnt
         mean2 += delta * ($1 - avg)
       } 
END    { print_output() }                             # print results for last file
' param_[ADGKM]_ratio_re_truncated.txt

NOTES:

• remove 'FILENAME,' if you don't want to display each file's name
• assumes all files have at least one line of input otherwise some additional logic may be needed to handle 'empty' files
• unable to test since there's no sample input nor expected output
• I'm assuming OP's current code works as expected (ie, I haven't attempted to validate OP's current code)

> I want to repeat this command line at once but replace "A" in the file
> name with "D, G, K, M" etc. other than typing the line every time

I suggest taking look at BEGINFILE/ENDFILE and keeping in mind difference between FNR (number of row inside file) and NR (global number of row), consider following example, I have file1.txt with content

1
2
3

file2.txt with content

10
20
30
40

file3.txt with content

100
200
300
400
500

and want to show total and number of records in each file, then I could do

awk 'BEGINFILE{total=0}{total+=$1}ENDFILE{print FILENAME, "total value is", total, "number of records is", FNR}' file1.txt file2.txt file3.txt

getting output

file1.txt total value is 6 number of records is 3
file2.txt total value is 100 number of records is 4
file3.txt total value is 1500 number of records is 5

(tested in GNU Awk 5.1.0)