VBA For Each - Populate Blank Cells with Data Above

The tab is named "Stack" (not pictured). I am looking to populate blanks based on the value above with intermittent changes among the blanks.

The below code generates no errors, but does not populate anything in the blank cells. I confirmed with sheet formulas that "" is TRUE as expected (e.g. =A4="" returns TRUE).

Sub populapotato()

Dim myRange As Range
Dim potato As Variant

Set myRange = ActiveWorkbook.Sheets("Stack").Range("A4:A50")

For Each potato In myRange

'End loop at blank data cell
    If potato.Offset(0, 1).Value = "" Then
        Exit For
            End If

'Populate File Name col if blank
        If potato = "" Then
        potato = potato.Offset(-1, 0).Value
            Else
                End If
                
Next potato

End Sub

Use Range as the type for potato, and use .Value when assigning values to cells/ranges:

Sub populapotato()
    Dim myRange As Range, potato As Range
    
    Set myRange = ActiveWorkbook.Sheets("Stack").Range("A4:A16")
    For Each potato In myRange.Cells
        Debug.Print potato.Address, potato.Value = ""
        If Len(potato.Offset(0, 1).Value) = 0 Then Exit For
        If Len(potato.Value) = 0 Then potato.Value = potato.Offset(-1, 0).Value
    Next potato
End Sub