How can I loop through a list of %let statements?

I have five groups of %let statements I would like to loop through. I have been commenting out each group but I just realized I have to do this for about 30 other groups. Here are the five groups I need to loop through:

%let test_code = 5622;
%let total_categories = 5;
%let cat_1_name = Students as Learners;
%let cat_2_name = Instructional Process;
%let cat_3_name = Assessment;
%let cat_4_name = Professional Development, Leadership, and Community;
%let cat_5_name = Analysis of Instructional Scenarios;

%let test_code = 5004;
%let total_categories = 3;
%let cat_1_name = U.S. History, Government, Citizenship;
%let cat_2_name = Geography, Anthropology, Sociology;
%let cat_3_name = World History, Economics;

%let test_code = 5003;
%let total_categories = 3;
%let cat_1_name = Numbers and Operations;
%let cat_2_name = Algebraic Thinking;
%let cat_3_name = Geometry and Measurement, Data, Statistics, and Probability;

%let test_code = 5002;
%let total_categories = 2;
%let cat_1_name = Reading;
%let cat_2_name = Writing, Speaking, Listening;

%let test_code = 5005;
%let total_categories = 3;
%let cat_1_name = Earth Science;
%let cat_2_name = Life Science;
%let cat_3_name = Physical Science;

The rest of the code uses the total_categories variable to format based on the total number of categories included in each test. Apologies if this has already been asked. Any advice is appreciated.

Your question suggests that you're ready to move on from simply using macro variables, to using macros. If you're not familiar with macros, you can think of a macro as a block of code that you want to execute multiple times, and each time you run it you want to provide different values for macro variables in the code. So here's an example of a macro that will run PROC PRINT, that allows you to specify values for seven macro variables when you run the macro. The macro variables are used in the TITLE statement.

%macro dosomething
  (test_code=
  ,total_categories=
  ,cat_1_name=
  ,cat_2_name=
  ,cat_3_name=
  ,cat_4_name=
  ,cat_5_name=
   )
;
   
title1 "test_code=&test_code total_categories=&total_categories" ;
title2 "cat_1_name=&cat_1_name cat_2_name=&cat_2_name cat_3_name=&cat_3_name cat_4_name=&cat_4_name cat_5_name=&cat_5_name" ;

proc print data=sashelp.class ;
run ;

title1 ;

%mend dosomething ;

When you run that code you won't get any results. SAS compiles the macro. You can then run the macro like:

options mprint ;

%dosomething(
  test_code = 5622
 ,total_categories = 5
 ,cat_1_name = Students as Learners
 ,cat_2_name = Instructional Process
 ,cat_3_name = Assessment
 ,cat_4_name = %str(Professional Development, Leadership, and Community)  /*%str is needed to hide the commas in the value*/
 ,cat_5_name = Analysis of Instructional Scenarios
) 

And you can run it for the second time like:

%dosomething(
  test_code = 5004
 ,total_categories = 3
 ,cat_1_name = %str(U.S. History, Government, Citizenship)
 ,cat_2_name = %str(Geography, Anthropology, Sociology)
 ,cat_3_name = %str(World History, Economics)
) 

If you need to run your block of code 5 times, you can write 5 macro calls like above. If you need to run the block of code 30 times, you could write 30 macro calls like above. Or you can look into ways to store the values for the macro variables in a dataset, and then use that dataset to drive 30 macro calls. This is a more advanced technique, it can be done with CALL EXECUTE or other methods.