Storing PROC MEANS data and using mean in another dataset

Is there a way to store the data from the PROC MEANS procedure and store the mean and standard deviation to be used in another dataset? I want to be able to take the mean and standard deviation to filter out the outliers from the dataset. I have just copied and pasted the data from proc means to do this however is there a way to do this automatically?

This is what I have been trying but I cannot use the variables orgMean and orgSTD in the data outliers.

DATA original;

PROC MEANS DATA = original;
VAR importantVar; 
OUTPUT OUT=originalMeans;
   MEAN = orgMean
   STD = orgSTD;

and now I want to use the orgMean and orgSTD to make a new dataset for outliers from the original data

DATA outliers;
SET original;
IF (importantVar > orgMean + 2*STD) 

Is there an easier way to do this? I am very new to SAS and I cannot seem to find the answer online with searching, I would prefer if I could use the variables from the PROC Means, as it could be useful in the other code I need to write.

You are asking how to combine an existing dataset with one that has only one observation. An easy way to do that is to SET the one observation dataset only once, on the first pass of the data step.

data outliers;
  set original;
  if _n_=1 then set originalMeans;
  if importantVar > (orgMean + 2*STD);
run;

The easiest way is to store them into macro variables with symputx() in a subsequent data step. Macros and macro variables are an advanced but important concept in SAS. I recommend reading about them in Introduction to SAS Macro Language.

In short, the SAS Macro language is basically a very fancy copy/paste where you can store text in variables and use them in open code. You call those variables with an &, like this: &foo. &foo is a macro variable that could store some text. You can give it text a number of ways, such as:

%let foo = bar;

If you type %put &foo, it will write bar to the log. Another way to store text to macro variables it through the symputx() function in the data step. We're going to use the data step to save your mean and std into two macro variables, then pass those into your final data step. Here's what that looks like.

PROC MEANS DATA = original;
    VAR importantVar; 
    OUTPUT OUT=originalMeans
        MEAN = orgMean
        STD = orgSTD
    ;
run;

data _null_;
    set originalMeans;
    call symputx('orgMean', orgMean);
    call symputx('std', orgStd);
run;

data want;
    set original;
    where importantVar > &orgMean. + 2*&std.;
run;

What's happening here?

call symputx() saves the variables orgMean and orgStd into the macro variables &orgMean and &std respectively. We can use these wherever we want in open code.

Note that our where statement looks like this:

data want;
    set original;
    where importantVar > &orgMean + 2*&std;
run;

Suppose your mean is 2 and std is 5. As far as SAS is concerned, it looks like this when the macro variables resolve:

data want;
    set original;
    where importantVar > 2. + 2*5;
run;

In other words, &orgMean resolves to 2 and &std resolves to 5. This happens before the data step is compiled. If you take a SAS macro language course, you'll learn all about these concepts and how powerful they are.

The PROC MEANS approach followed by a DATA step is a good one. Since you mention you're new to SAS, if you have experience with SQL, you might consider a PROC SQL approach. PROC SQL has a feature which is not part of the SQL standard, which will automatically "remerge" summary statistics back onto row data. This makes it straight-forward to write a query to select the outliers, e.g.:

proc sql ;
  create table HighOutliers 
  as select *
  from sashelp.cars
  having MSRP > (mean(MSRP) + 2*std(MSRP))
  ;
quit ;