Divide values of a data set by nrows of another data set

suppose to have the following table:

> ID Value
> A 234
> B 231
> C 223
> D 167
> E 57

And you know that the number of rows of another data set is "xxx", for example 1,234.
Now, you want to divide each row ("Value" column) by the "xxx". I would like not to show explicitly the value of "xxx" because depending on the data set it could change.
Desired output:

> ID Value
> A 0.189
> B 0.187
> C 0.180
> D 0.135
> E 0.046

Can anyone help me please?

Given data like:

data have ;
  input ID $1. Value ;
  cards ; 
A 234
B 231
C 223
D 167
E 57
;

data other ;
  do id=1 to 1234 ;
    output ;
  end ;
run ;

You can use the SET statement with NOBS option to determine the number of records in OTHER.

data want ;
  set have ;
  if 0 then set other (drop=id) nobs=nobs ;
  Value2=Value/nobs ;
run ;

You can get the number of obs in a data set using the NOBS= SET statement option.

data value;
    input id:$1. value;
    cards;
    A       234
    B       231
    C       223
    D       167
    E       57
    ;;;;
run;
data temp;
    if 0 then set sashelp.class(drop=_all_) nobs=nobs;
    set value;
    d = nobs;
    x = value/d;
run;
proc print;
run;

There are a lot of different ways to get the total number of rows of a dataset, but the most common one is to use a few function calls. SAS already knows the total number of rows in a SAS dataset, so you do not need to count them. We'll pull that attribute from the dataset, save it to a macro variable, then divide all the values of your dataset in a data step.

%let dsid = %sysfunc(open(otherdata));     * Open the dataset and create a dataset id;
%let nobs = %sysfunc(attrn(&dsid, nlobs)); * Get the number of rows;
%let rc   = %sysfunc(close(&dsid));        * Close it;

data want;
    set have;
    value = value/&nobs;
run;

Alternatively:

data _null_;
    set otherdata nobs=n;
    call symputx('nobs', n);
    stop;
run;

data want;
    set have;
    value = value/&nobs;
run;

You also create a macro that you can call any time you want the number of observations of a dataset.

%macro nobs(data);
    %let dsid = %sysfunc(open(&data));
    %let nobs = %sysfunc(attrn(&dsid, nlobs));
    %let rc   = %sysfunc(close(&dsid));

    &nobs
%mend;

Now you can call %nobs whenever you want the total number of observations of a dataset.

data want;
    set have;
    value = value/%nobs(otherdata);
run;