SAS running a macro loop for n and p generating variables--> then creating a macro loop which has n and p as arguments

As the title states im trying to illustrate the law of large numbers through bernoulli(p) by running a macro loop to generate output in the log. However with the following code i am getting no output what so ever. Following code is below.

Code:

<!-- begin snippet: js hide: false console: true babel: false -->

<!-- language: lang-html -->

%macro LLN(n=10, p=0.6);
  %let sum = 0; %let mean = 0;
   data LLN; 
%do i = 1 %to &n;
x = rand("Bernoulli", &p); 
sum = sum + x;
mean = sum / i;
output; 
%end;
run;
%mend LLN;

<!-- end snippet -->

There are three points to improve:

1. You don't really need a macro. The do loop can be done in normal data step.
2. If you want to use macro variable i in your data step to join the calculation with data step variables, you should use &i.
3. The initial way of sum and mean is for macro variable, but you truly use them as data step variables.

I suggest you to use a data step:

data test;
  do i=1 to 10000;
    x = rand("Bernoulli", 0.6); 
    sum + x;
    mean = sum / i;
  end;
run;

A macro-ization of @whymath code would take argument for the loop <code>max</code> and <code>p</code> parameter of the rand() function.

Example:

A use of this macro creates a single data set. Why mean is calculated at each loop iteration? Do you want the intermediate mean in you study of LLN? If so, add an OUTPUT inside the loop. If not, after the loop concludes compute mean = sum / &N. You probably also want the macro to accept a random number seed for reproducibility in future runs.

%macro LLN (N=1000, p=0.6, out=, seed=.);  /* . is a random seed */
  data &out (label="LLN: N=&N, p=&p");
    call streaminit(&seed);
    do i=1 to &N;
      x = rand("Bernoulli", &p); 
      sum + x;
      mean = sum / i;
    end;
    * mean = sum / &N; * maybe? ;
  run;

%mend;

However, you can also compute the sum & mean for various combinations of N & p in a single data step and do some sort of visualizaton involving by and group concepts.

data LLN_study;
  do p = 0.1, 0.2, 0.4, 0.5, 0.6, 0.8, 0.9;
    do N = 1e3, 1e4, 1e5;

      call missing (sum, mean);
      do i = 1 to N;
        x = rand("Bernoulli", p); 
        sum + x;
        mean = sum / i;
        * OUTPUT ;  /* uncomment if you want every sum & mean for each N,p,i */
      end;
      * mean = sum / N;
      * OUTPUT ;  /* uncomment if you want every sum & mean for each N,p */
    end; /* p variation */
  end; /* N variation */
run;

proc sgplot data=LLN_study;
  series y=mean x=i / group=N;
  where mod(i,10)=1;
  by p;
run;

Get the SAS code to work properly for some value of N and P first.

So this code will create 10 observations.

data LLN; 
  do i = 1 to 10;
    x = rand("Bernoulli", 0.6); 
    sum + x;
    mean = sum / i;
    output; 
  end;
run;

If you just want the final observation and not all of the partial sums then either move the OUTPUT statement outside the loop, or delete it since SAS will write the observation at the end of the step when there is no explicit output statement.

data LLN; 
  do i = 1 to 10;
    x = rand("Bernoulli", 0.6); 
    sum + x;
  end;
  mean = sum / 10;
run;

Now you can try to convert it to a macro by replacing 10 with &N and 0.6 with &P.

%let n=10;
%let p=0.6;
data LLN; 
  do i = 1 to &n;
    x = rand("Bernoulli", &p); 
    sum + x;
  end;
  mean = sum / &n;
run;

Once you see that works you are ready to create a macro with parameters N and P.

%macro LLN(n, p);
data LLN; 
  do i = 1 to &n;
    x = rand("Bernoulli", &p); 
    sum + x;
  end;
  mean = sum / &n;
run;
%mend LLN;
%LLN(n=10,p=0.6)