Macro that import data from a folder to an excel doc

I am writing a VBA code that automatically fetches the newest ATP report file from the specified folder, extracts relevant data from it, and pastes that data into the "Details-lines" worksheet of the main workbook based on matching "Item" values. However, I receive an error message that there is no data in the specified folder. I created a folder that appears in my desktop named ATP Report and it contains files that get updated daily, every day, a new file will be uploaded named ATP report 20230731 base don the date. What is exactly the problem?

Private Sub Workbook_Open()
    ImportDataFromNewestATPReportFile
End Sub

Sub ImportDataFromNewestATPReportFile()
    Dim mainWorkbook As Workbook
    Dim dataWorkbook As Workbook
    Dim mainWorksheet As Worksheet
    Dim dataWorksheet As Worksheet
    Dim dataFilePath As String
    Dim dataLastRow As Long
    Dim mainLastRow As Long
    Dim dataFilename As String
    Dim newestFile As String
    Dim newestDate As Date

    ' Update the folder path for the data files in the "ATP report" folder on your desktop
    dataFilePath = Environ("USERPROFILE") & "\Desktop\ATP report\"

    ' Print the value of the dataFilePath variable to the Immediate Window
    Debug.Print "Folder Path: " & dataFilePath

    ' Set references to the main workbook and worksheet
    Set mainWorkbook = ThisWorkbook
    Set mainWorksheet = mainWorkbook.Sheets("Details-lines")

    ' Initialize variables to store the information about the newest file
    newestDate = Date ' Set an initial date value to the minimum possible date

    ' Loop through the files in the folder and find the newest file
    dataFilename = Dir(dataFilePath & "ATP Report *.xlsx") ' Search for files with names starting with "ATP Report"
    Do While dataFilename <> ""
        ' Extract the date part from the filename (assuming it is in the format "ATP Report yyyymmdd.xlsx")
        Dim dateString As String
        dateString = Mid(dataFilename, 12, 8) ' Extract the date string from the filename (skipping "ATP Report" prefix)
        Dim fileDate As Date
        On Error Resume Next
        fileDate = DateSerial(CInt(Mid(dateString, 1, 4)), CInt(Mid(dateString, 5, 2)), CInt(Mid(dateString, 7, 2)))
        On Error GoTo 0

        ' Check if the extracted date is valid and greater than the current newestDate
        If IsDate(fileDate) And fileDate > newestDate Then
            newestDate = fileDate
            newestFile = dataFilename
        End If

        dataFilename = Dir
    Loop

    ' Check if there is at least one file in the folder
    If newestFile <> "" Then
        ' Open the newest data workbook
        Set dataWorkbook = Workbooks.Open(dataFilePath & newestFile)
        Set dataWorksheet = dataWorkbook.Sheets("ATP Report")

        ' Find the last row with data in the data worksheet
        dataLastRow = dataWorksheet.Cells(dataWorksheet.Rows.Count, "A").End(xlUp).Row

        ' Find the last row with data in the main worksheet
        mainLastRow = mainWorksheet.Cells(mainWorksheet.Rows.Count, "A").End(xlUp).Row

        ' Loop through each Item in the main worksheet
        Dim i As Long
        For i = 2 To mainLastRow ' Assuming data starts from row 2 in the main worksheet
            Dim Item As String
            Item = mainWorksheet.Cells(i, "A").Value ' Assuming Item are in column A

            ' Search for the Item in the data worksheet
            Dim j As Long
            For j = 2 To dataLastRow ' Assuming data starts from row 2 in the data worksheet
                If dataWorksheet.Cells(j, "A").Value = Item Then ' Assuming Item are in column A
                    ' Copy ATP and Intransit data to columns U and V in the main worksheet
                    mainWorksheet.Cells(i, "U").Value = dataWorksheet.Cells(j, "B").Value ' Assuming ATP data is in column B
                    mainWorksheet.Cells(i, "V").Value = dataWorksheet.Cells(j, "C").Value ' Assuming Intransit data is in column C
                    Exit For ' Exit the inner loop since the Item is found
                End If
            Next j
        Next i

        Application.CutCopyMode = False ' Clear clipboard

        ' Close the data workbook without saving
        dataWorkbook.Close False
    Else
        MsgBox "No data files found in the specified folder.", vbExclamation
    End If
End Sub

I need clarification and help so i can resolve the problem and be able to run the macro successfully.

I'd suggest pulling out the various parts of your code into separate methods, so they're more-easily testable/re-usable.

Eg: for getting the latest report

Sub Tester()
    
    Dim latestReport As String
    
    latestReport = NewestReport("C:\Temp\VBA\")
    
    Debug.Print "LatestReport", IIf(Len(latestReport) > 0, latestReport, "Not found")

End Sub

'Find the file name for the newest report at `dataFilePath`
Function NewestReport(dataFilePath As String) As String
    Dim newestdate As Date, reportDate As Variant, fName As String, newestFile As String
    fName = Dir(dataFilePath & "ATP Report *.xlsx") ' Search for files with names starting with "ATP Report"
    Do While fName <> ""
        reportDate = GetReportDate(fName)
        If Not IsEmpty(reportDate) Then
            newestdate = reportDate
            newestFile = fName
        End If
        fName = Dir
    Loop
    NewestReport = newestFile
End Function

'return a Date value if a valid date is extracted from the file name, or Empty if couldn't get a date
Function GetReportDate(fileName) As Variant
    Dim rv As Variant
    On Error Resume Next 'ignore error if not valid date
    rv = DateSerial(CInt(Mid(fileName, 12, 4)), _
                    CInt(Mid(fileName, 16, 2)), _
                    CInt(Mid(fileName, 18, 2)))
    On Error GoTo 0
    Debug.Print fileName, rv
    GetReportDate = rv
End Function