My VBA code to separate a filter in different worksheets is creating empty worksheets

Sub um_separatabelanosfiltros()
Dim r As Integer, brand As String, ws As Worksheet
Set ws = ActiveSheet
ws.Range("A1:C1").AutoFilter
r = 1
Do
    r = r + 1
    brand = ws.Range("A" & r).Value
    On Error Resume Next
    If Sheets(brand) Is Nothing Then
        ws.Range("A1:C1").AutoFilter field:=1, Criteria1:=brand
        ws.Range("A1").CurrentRegion.SpecialCells(xlCellTypeVisible).Copy
        Sheets.Add.Name = brand
        Sheets(brand).Paste
        ws.ShowAllData
    End If
Loop While ws.Range("A" & r + 1).Value <> ""
End Sub

With this code i can separate a worksheet by the filters in the A1 cell, but i tried to use it in a different dataset and it kept creating empty worksheets, any sugestion and or help?

Iv tried alot of thing and my conclusion is that some how the data is screwing it up, i just dont know how it can do that or how to fix it

If you don't have a ready list of unique items in the column you want to split on, you can do it without autofilter:

Sub um_separatabelanosfiltros()
    
    Dim brand As String, wsData As Worksheet, wsBrand As Worksheet
    Dim wb As Workbook, cBrand As Range
    
    Set wb = ActiveWorkbook
    Set wsData = ActiveSheet
    
    Set cBrand = wsData.Range("A2")   'first brand
    
    Do While Len(cBrand.Value) > 0
        
        brand = cBrand.Value
        
        Set wsBrand = Nothing  'clear sheet reference
        On Error Resume Next   'ignore error if no sheet match
        Set wsBrand = wb.Worksheets(brand)
        On Error GoTo 0        'stop ignoring errors ASAP
        
        If wsBrand Is Nothing Then  'need to create a new sheet?
            Set wsBrand = wb.Worksheets.Add(after:=wb.Worksheets(wb.Worksheets.Count))
            wsBrand.name = brand
            wsData.Rows(1).Copy wsBrand.Range("A1") 'copy headers
        End If
        
        cBrand.EntireRow.Copy wsBrand.Cells(Rows.Count, 1).End(xlUp).Offset(1)
        Set cBrand = cBrand.Offset(1) 'Next row of data
    Loop
End Sub