VBA to move to next sheet if certain condition is not met

I have an up a running code. The code takes an input string from the user, finds it in all of the sheets. When found, performs other tasks for that particular string (like copying necessary associated data) and then spits out that data onto a blank sheet. The issue is that there are sheets where user defined string is not present. In such a case, it fails and gives error (naturally it is unable to find what its been asked to find). Now my question is, is there a way to skip the sheet and move to the next sheet incase if VBA code is unable to find user input string? I tried with if statement, but within if, next ws doesn't work.

Sub Get_w_Data()

Dim ws As Worksheet
Dim shtName As String
Dim exists As Boolean
Dim i As Integer
Dim wName As String
Dim mydate As Date

Dim i_DateCounter As Integer
Dim DataColCounter As Integer
Dim wData(1 To 1, 1 To 11) As Variant
Dim Target As Range
Dim DataToDelete As Range

Application.ScreenUpdating = True

shtName = "Test Sheet"
wName = Sheets(shtName).Range("C1").Value

    For i = 1 To Worksheets.Count
        If Worksheets(i).Name = shtName Then
            exists = True
        End If
    Next i

    If Not exists Then
        ThisWorkbook.Worksheets.Add(After:=ThisWorkbook.Sheets(Sheets.Count)).Name = shtName
    End If
      
'===========================================================================================
' ************* Deleting data from previously selected wName
'===========================================================================================

    With Worksheets("Test Sheet")

        Set DataToDelete = .Range("B6:K6", .Range("B" & .Rows.Count).End(xlUp))

        DataToDelete.ClearContents


    End With
                 
'********************************************************************************************
    For Each ws In ThisWorkbook.Worksheets
    
     ws.Select
     
        If ws.Name = shtName Then
            Exit Sub
        End If
        
        
  Range("B25:U64").Find(What:=wName, MatchCase:=True, LookAt:=xlWhole).Select
' when wName doesn't exist in any of the sheets, code fails. How can I setup the code in a way that when wName doesn't exist, it skips to next ws? 

''' some code to perform some task            
    
    Next ws
           
          
    Application.ScreenUpdating = False
    
End Sub

Skipping a Worksheet in a Loop When No Cell Found

<!-- language: lang-vb -->

Sub Get_w_Data() ' surely you can do better!
' Define constants.
Const SRC_RANGE As String = "B25:U64"
Const DST_SHEET As String = "Test Sheet"
Const DST_FIRST_ROW As String = "B6:K6"
' Reference the workbook.
Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
' Reference the destination worksheet.
' Attempt to reference the destination worksheet.
Dim dws As Worksheet
On Error Resume Next
Set dws = wb.Sheets(DST_SHEET)
On Error GoTo 0
' First turn it off, later turn it back on!
Application.ScreenUpdating = False
' Check if the attempt was successful.
If dws Is Nothing Then ' worksheet not referenced (not found).
MsgBox "The worksheet """ & DST_SHEET & """ was not found.", _
vbCritical
Exit Sub
' How would the following be useful since you later would be reading
' the value in cell `C1` from an empty worksheet?
'Set dws = wb.Sheets.Add(After:=wb.Sheets(wb.Sheets.Count))
'dws.Name = DST_SHEET
End If
' Store the search string in a variable.
' Maybe use something less generic and more readable like 'WorkerName'.
Dim wName As String: wName = CStr(dws.Range("C1").Value)
' Clear previous data in the destination worksheet.
With dws.Range(DST_FIRST_ROW)
' This clears from the first row to the bottom row of the worksheet
' but it's efficient anyway.
.Resize(dws.Rows.Count - .Row + 1).ClearContents
End With
' The loop. Shortly describe what you're doing in it.
' Declare new variables used in the loop.
Dim sws As Worksheet, srg As Range, sCell As Range
'    Dim Target As Range
'    Dim wData(1 To 1, 1 To 11) As Variant
'    Dim i As Long
'    Dim mydate As Date
'    Dim i_DateCounter As Long
'    Dim DataColCounter As Long
For Each sws In wb.Worksheets
' Check if it's not the destination worksheet.
If StrComp(sws.Name, DST_SHEET, vbTextCompare) <> 0 Then ' it's not
Set srg = sws.Range(SRC_RANGE)
' The parameters are setup to find the top-most left-most
' occurrence of the search string.
Set sCell = srg.Find(What:=wName, _
After:=srg.Cells(srg.Cells.CountLarge), LookIn:=xlValues, _
LookAt:=xlWhole, SearchOrder:=xlByRows, MatchCase:=True)
' are you sure about 'MatchCase' i.e. 'Peter <> peter'?
If Not sCell Is Nothing Then
' some code to perform some task
'Else ' a cell equal to 'wName' was not found; do nothing
End If
'Else ' it's the destination worksheet; do nothing
End If
Next sws
' Now turn it back on.
Application.ScreenUpdating = True
' Inform.
MsgBox "Task performed.", vbInformation
End Sub

You can use the try-concept:

Private Function tryFindRangeInSheet(rgToSearchIn As Range, strFindText As String, _
ByRef rgFound As Range) As Boolean
On Error Resume Next
Set rgFound = rgToSearchIn.Find(What:=strFindText, MatchCase:=True, LookAt:=xlWhole)
If Not rgFound Is Nothing Then tryFindRangeInSheet = True
On Error GoTo 0
End Function

Like this you can easily use the function within your main routine:

Public Sub get_w_Data()
Dim wName As String
Dim rgToSearchIn As Range, rgFound As Range
Dim ws As Worksheet
For Each ws In ThisWorkbook.Worksheets
Set rgToSearchIn = ws.Range("B25:U64")
If tryFindRangeInSheet(rgToSearchIn, wName, rgFound) = True Then
'do what you need with rgFound
End If
Next
End Sub