Filter on multiple columns and compile value to main workbook

I have multiple workbooks for each date e.g. Workbook_20230505 with data as below:

I am able to compile the latest time given criteria (where Staff <> "SYSTEM" or "VOID") to a main workbook as below:

Update: The Date column has all the days of the month, but not all days there is a workbook. If there is no workbook for that day, leave the result at Latest Time as blank and move to the next day as below. Also, the table below shall start from C10.

This is the code:

Sub GetMax()
Dim FolderPath As String
Dim FileName As String
Dim wb As Workbook
Dim ws As Worksheet
Dim MaxValue As Date
Dim DatePart As String
Dim LastRow As Long
Dim arr
Application.ScreenUpdating = False
' Update your folder name
FolderPath = "D:\Temp\"
' Clean activesheet and set format
With ActiveSheet
.UsedRange.Clear
.[A1:B1].Value = Array("Date", "LatestTime")
.Columns(1).NumberFormat = "mm/dd/yyyy"
.Columns(2).NumberFormat = "h:mm:ss AM/PM"
End With
' Retrieve files with "Workbook_*.xlsx"
FileName = Dir(FolderPath & "Workbook_*.xlsx")
Do While FileName <> ""
DatePart = Split(FileName, "_")(1)
Set wb = Workbooks.Open(FolderPath & FileName)
Set ws = wb.Sheets(1)
' Get max value of column B
arr = ws.UsedRange.Value
MaxValue = 0
If UBound(arr, 2) >= 3 Then
For i = 2 To UBound(arr)
If InStr("SYSTEM|VOID", UCase(arr(i, 3))) = 0 Then
If MaxValue < arr(i, 2) Then MaxValue = arr(i, 2)
End If
Next
End If
wb.Close SaveChanges:=False
With ThisWorkbook.Sheets(1)
LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
If LastRow > 1 Or .Cells(LastRow, 1) <> "" Then LastRow = LastRow + 1
.Cells(LastRow, "A").Value = DateSerial(CInt(Mid(DatePart, 1, 4)), CInt(Mid(DatePart, 5, 2)), CInt(Mid(DatePart, 7, 2)))
.Cells(LastRow, "B").Value = MaxValue
End With
FileName = Dir
Loop
Application.ScreenUpdating = True
End Sub

(Solution from https://stackoverflow.com/questions/76748131/compile-value-from-each-workbook-to-main-workbook/)

How do I modify the above code if I have an additional column for Contract Date, and wish to filter for Contract Date as well as Staff column?

I wish to filter the Contract Date according to the workbook date.

Note: My data starts on row 3 (row 2 is blank)

Appreciate the help!

I have updated the code based on the new requirements. Multiple lines have been modified. Dictionary object is used to store the maxvlue.

Sub GetMax()
Dim FolderPath As String
Dim FileName As String
Dim wb As Workbook
Dim ws As Worksheet
Dim MaxValue As Date
Dim DatePart As String
Dim LastRow As Long
Dim arr, dic, rngRes As Range
Set dic = CreateObject("scripting.dictionary")
Application.ScreenUpdating = False
' Update your folder name
FolderPath = "D:\Temp\"
' Retrieve files with "Workbook_*.xlsx"
FileName = Dir(FolderPath & "Workbook_*.xlsx")
Do While FileName <> ""
DatePart = Split(Split(FileName, "_")(1), ".")(0)
Set wb = Workbooks.Open(FolderPath & FileName)
Set ws = wb.Sheets(1)
' Get data from worksheet
arr = ws.UsedRange.Value
MaxValue = 0
If UBound(arr, 2) >= 3 Then
For i = 3 To UBound(arr) ' Start from row 3
' filter Data and Staff
If InStr("SYSTEM|VOID", UCase(arr(i, 4))) = 0 And _
CStr(arr(i, 2)) = DatePart Then
arr(i, 3) = CDate(arr(i, 3))
If MaxValue < arr(i, 3) Then MaxValue = arr(i, 3)
End If
Next
End If
' store MaxValue in Dictionary
dic(DatePart) = MaxValue
wb.Close SaveChanges:=False
FileName = Dir
Loop
With ActiveSheet
LastRow = .Cells(.Rows.Count, "C").End(xlUp).Row
Set rngRes = .Range("C10:D" & LastRow)
rngRes.Columns(2).NumberFormat = "h:mm:ss AM/PM"
arr = rngRes.Value
For i = 2 To UBound(arr)
If VBA.IsDate(arr(i, 1)) Then
DatePart = Format(arr(i, 1), "yyyymmdd")
If dic.exists(DatePart) Then
arr(i, 2) = dic(DatePart)
Else
arr(i, 2) = ""
End If
End If
Next
rngRes.Value = arr
End With
Set dic = Nothing
Application.ScreenUpdating = True
End Sub