Updating fields in headers, footers, and main story in Word on file open

I used code from questions on this site that all worked, just had to manually run them. Below is a code example.

Why isn't this working automatically when I open the document?

Private Sub Document_AutoOpen()
    UpdateAllFields
End Sub

Sub UpdateAllFields()
    Dim rng As Range
    Dim sec As Section
    Dim hdrFtr As HeaderFooter
    
    ' Update fields in the body
    For Each rng In ActiveDocument.StoryRanges
        UpdateFieldsInRange rng
        Do While Not (rng.NextStoryRange Is Nothing)
            Set rng = rng.NextStoryRange
            UpdateFieldsInRange rng
        Loop
    Next rng
    
    ' Update fields in headers and footers
    For Each sec In ActiveDocument.Sections
        For Each hdrFtr In sec.Headers
            UpdateFieldsInRange hdrFtr.Range
        Next hdrFtr
        
        For Each hdrFtr In sec.Footers
            UpdateFieldsInRange hdrFtr.Range
        Next hdrFtr
    Next sec
End Sub

Sub UpdateFieldsInRange(rng As Range)
    Dim fld As Field
    
    For Each fld In rng.Fields
        fld.Update
    Next fld
End Sub

Wherever you got Document_AutoOpen from, it's wrong. You either need a routine named AutoOpen in a standard module, or, in the ThisDocument module, you have an event handler named Document_Open.