sed for each empty line or match increment field

Example of data generated by software binary:

Label 1: "AAA"
Label 2: "BBB"
Label 3: "CCC"

Label 1: "XXX"
Label 2: "YYY"
Label 3: "ZZZ"

Each label "group" is separated by new line or starting with "Label 1", can have n groups (so need to get lab, lab2, lab3 in desired output and so on).

Current output:

lab,Label 1,AAA,
lab,Label 2,BBB,
lab,Label 3,CCC,
lab,Label 1,XXX,
lab,Label 2,YYY,
lab,Label 3,ZZZ,

Existing code:

labels="$(${binary} -list | sed -e '/^$/d')"
echo "$labels" | sed -e 's/: \{1,\}/,/g' -e 's/"//g' -e 's/, /,/g' -e "s|^|lab,|g" -e 's/$/,/g'

Desired output:

lab,Label 1,AAA,
lab,Label 2,BBB,
lab,Label 3,CCC,
lab2,Label 1,XXX,
lab2,Label 2,YYY,
lab2,Label 3,ZZZ,

Since an empty line is record separator, here is a way to do this in awk using empty RS:

awk -v RS= '{
   gsub(/(^|\n)/, "&lab" (NR>1?NR:"") ","); gsub(/(: )?"/, ",")
} 1' file

lab,Label 1,AAA,
lab,Label 2,BBB,
lab,Label 3,CCC,
lab2,Label 1,XXX,
lab2,Label 2,YYY,
lab2,Label 3,ZZZ,

awk is probably a better choice here:

awk -F': "|"' -v OFS=, '$1=="Label 1" {p="lab"n; n+=n?1:2} /./{print p,$1,$2,""}'

Declare the input field separator as either : " or " (-F': "|"') and the output field separator as a comma (-v OFS=,). If the first field of the current line is "Label 1", set variable p to concatenation of "lab" and value of variable n, if n is defined increment it by 1, else by 2. Finally, if the current line is not empty (/./) print p, the first and second fields, and an empty last field (for the trailing comma), separated by OFS.

Note: uninitialized variables (like n) evaluate as the empty string or numeric value 0, depending on the evaluation context. Here, in p="lab"n, the evaluation context of n is string concatenation. So the first time n is evaluated as empty string and p takes value "lab". The other times n has value 2, 3, 4... and p takes values "lab2", "lab3", "lab4"...

Using any awk:

$ awk -v OFS=',' '
    NF { gsub(/(: )?"/,OFS); print "lab" n, $0; next }
    { n += (n ? 1 : 2) }
' file
lab,Label 1,AAA,
lab,Label 2,BBB,
lab,Label 3,CCC,
lab2,Label 1,XXX,
lab2,Label 2,YYY,
lab2,Label 3,ZZZ,

With your shown samples please try following awk code.

awk -v OFS="," '
!NF{
  if(initCount==""){ initCount=2 }
  else             { initCount++ }
  next
}
{
  gsub(/: "/,",")
  sub(/"$/,",")
  print "lab"initCount,$0
}
'   Input_file

I will first transmute your code into GNU AWK and then apply changes to make it work as intended, let file.txt content be

Label 1: "AAA"
Label 2: "BBB"
Label 3: "CCC"

Label 1: "XXX"
Label 2: "YYY"
Label 3: "ZZZ"

then

awk '!/^$/{gsub(/: +/,",");gsub(/"/,"");gsub(/, /,",");gsub(/^/,"lab,");gsub(/$/,",");print}' file.txt

gives output

lab,Label 1,AAA,
lab,Label 2,BBB,
lab,Label 3,CCC,
lab,Label 1,XXX,
lab,Label 2,YYY,
lab,Label 3,ZZZ,

note that I kept all substitution global, even though ^ and $ might give at most 1 substitution each.

We need counter, which would increase when Label 1: is in line and which could be used during replacement, this can be done following way

awk '/Label 1:/{cnt+=1}!/^$/{gsub(/: +/,",");gsub(/"/,"");gsub(/, /,",");gsub(/^/,"lab" (cnt>1?cnt:"") ",");gsub(/$/,",");print}' file.txt

gives output

lab,Label 1,AAA,
lab,Label 2,BBB,
lab,Label 3,CCC,
lab2,Label 1,XXX,
lab2,Label 2,YYY,
lab2,Label 3,ZZZ,

Explanation: If there is Label 1: in line increase cnt by 1, if it is not yet set assume 0 and then increase, for not (!) empty line (/^$/) execute substitutions and print, for 4th gsub use lab followed by cnt if cnt above 1 else empty string followed by ,.

(tested in GNU Awk 5.1.0)

 echo '
Label 1: "AAA"
Label 2: "BBB"
Label 3: "CCC"

Label 1: "XXX"
Label 2: "YYY"
Label 3: "ZZZ"' | 

mawk 'NF ? $1 = (__)_ OFS $1 : (_+=!_)<_++' FS='(: )?"' OFS=, __='lab'

lab,Label 1,AAA,
lab,Label 2,BBB,
lab,Label 3,CCC,
lab2,Label 1,XXX,
lab2,Label 2,YYY,
lab2,Label 3,ZZZ,

$ awk -F': *"|"' '
  /^Label 1:/{i++} 
  !/^$/{printf("lab%s,%s,%s,\n", (i==1 ? "" : i), $1, $2)}
' file
lab,Label 1,AAA,
lab,Label 2,BBB,
lab,Label 3,CCC,
lab2,Label 1,XXX,
lab2,Label 2,YYY,
lab2,Label 3,ZZZ,

$ awk -F': *"|"' -v OFS="," '
  /^Label 1:/{i++} 
  !/^$/{$1=$1; print (i==1 ? "lab" : "lab"i), $0}
' file
lab,Label 1,AAA,
lab,Label 2,BBB,
lab,Label 3,CCC,
lab2,Label 1,XXX,
lab2,Label 2,YYY,
lab2,Label 3,ZZZ,

This might work for you (GNU sed):

sed -E ':a;$!{N;/\n$/!ba}
        y/"/,/;s/: |\n$//g;s/^/lab%,/mg;G
        :b;s/lab%(.*)\n(.*)/lab$((+1))\n/;tb
        s/(.*)\n.*/echo ""/e;s/^lab1,/lab,/mg
        x;s/.*/echo $((&+1))/e;x' file

Gather up groups of labels.

Translate "'s to commas.

Remove : 's and the empty line. Prepend lab% to each line and then append the hold space to the current batch of labels.

Replace each occurrence of the introduced % by a shell computation using the value stored in the hold space.

Replace the pattern space by an echo command that replaces the shell computations by an actual label number.

For the first set of labels remove the actual label number i.e. remove 1.

Prepare the hold space for the next batch of labels.

Print the result.

Alternative:

sed -E '/\S/{=;G;s/(.*)\n(.*)/echo "s#^#lab$((+1)),#"/e;b}
        x;s/.*/echo "$((&+1))"/e;x;=;s/.*/d/' file |
sed 'N;s/\n//' |
sed -f - -e 's/^lab1,/lab,/;s/: //;y/"/,/' file

Generate a sed script that amends/deletes each line of the input file.