Copy row if condition met using IF function, without blank rows

I am very new to macros and complicated Excel functions in general, so I am hoping this community can help me.

1

The top table is the Reversal Table. I have added a yes/no option in column F which feeds into an IF function in column D to reverse the +/- if column F shows y (Yes).
Then in the lower, Auto Reversals table, an IF function in column C populates if column D in Reversals is populated.
I have then used IF functions in the other columns, all referring to column C in Auto Reversals. If C is populated, the rest of the rows will be populated with the corresponding info.

Is there a way to do this without having lots of blank rows in the auto reversals table? Or a more streamlined way overall?

I am using IF functions as I didn't get on great with the VB, but this way is producing blank rows. I would like only the required rows (ie. Contain Y not N in column F) to be copied into the auto reversals table.

Here's a UDF which sort-of does the same thing as FILTER()

'Filter range `rng` according one or more tests and return all
'  rows which pass all the tests.
'Example usage:
'   =myfilter(A3:K10,F3:F10="fred")             one test
'   =myfilter(A3:K10,F3:F10="fred",H3:H10="y")  two tests
Function MyFilter(rng As Range, ParamArray tests())
    Dim rw As Range, i As Long, n As Long, c As Long, rOut As Long, arr, arrout()
    Dim arrOK() As Boolean, t As Long, anyRows As Boolean
    
    arr = rng.Value  'all input data as array
    ReDim arrOK(1 To UBound(arr, 1))
    
    'Find which rows satisfy all the tests
    'Each item in `tests()` is a 2-d array of True/False values
    For i = 1 To UBound(arr, 1)
        arrOK(i) = True 'defaults to true
        For t = 0 To UBound(tests)
            If Not tests(t)(i, 1) Then
                arrOK(i) = False 'flag skip row
                Exit For         'stop testing
            End If
        Next t
        If arrOK(i) = True Then n = n + 1 'increase row count if all tests passed
    Next i
    
    'if any good rows, populate the array for output
    If n > 0 Then
        ReDim arrout(1 To n, 1 To UBound(arr, 2))
        For i = 1 To UBound(arr)
            If arrOK(i) Then  'this row passed all tests?
                rOut = rOut + 1
                For c = 1 To UBound(arr, 2)
                    arrout(rOut, c) = arr(i, c)
                Next c
            End If
        Next i
    End If
    MyFilter = IIf(n > 0, arrout, "No rows")
End Function