Identify two digits in a cell are both odd or both even

I need your help on the following:

I have a number of records in two digit format.
For these I want to verify for the two separate digits to either both be even, or both be odd.

The purpose is to have a conditional formatting rule set for both being odd and another for both being even.

Please find some sample data below:

As you can see some numbers are marked bold. These numbers consist of 2 odd digits;
others are marked italic. These consist of 2 even digits.

Example:

13 consist of 1 and 3; both these numbers are odd. This should be formatted red (for example).

29 consists of 2 and 9; 2 being even, but 9 being odd. This should not be formatted.

42 consists of 4 and 2; both being even numbers. This should be formatted green (as an example)

I have no clue how to separate the check of the single digits within the same cell.

both digits in cell are odd

This checks the first and second digit in a cell to be odd:
=AND(ISODD(--MID(A1,ROW($1:$2),1)))

Or shorter, as suggested by VBasics2008 (thanks!):
=AND(ISODD(--MID(A1,{1;2},1)))

2 digits in cell are both either odd or even

In your question you formatted both numbers that had both digits odd and also the ones that had both even. In that case use =SUM(MOD(--MID(A1,ROW($1:$2),1),2))<>1

Or =SUM(MOD(--MID(A1,{1;2},1),2))<>1

Both digits in cell are even

If you want a separate for both being even, use =AND(ISEVEN(--MID(A1,ROW($1:$2),1)))

Or =AND(ISEVEN(--MID(A1,{1;2},1)))

If I understand you correctly, this should work to check both digits are odd or even:

=OR(AND(ISEVEN(QUOTIENT(A1,10)),ISEVEN(MOD(A1,10))),AND(ISODD(QUOTIENT(A1,10)),ISODD(MOD(A1,10))))

Explanation:

• A1 is here the cell with the 2 digit number
• Just divide the number by 10 via QUOTIENT and MOD to separate the
  respective digits.
• check the conditions with ISEVEN and ISODD accordingly

Edit:

A shorter version to check both digits are odd or both are even:

=ISEVEN(SUM(QUOTIENT(A1,10),MOD(A1,10)))

Edit2:

Use the respective AND() sections of the first formula to check for even or odd separately (missed your comment earlier)

btw, this solution does not require any string operation on the number

You wrote in comments: "if both digit odd then color red or both digit even color green"

So you need two conditional formating rules. One for the red and one for the green.

WHEN THE TWO DIGITS ARE ODD THE NEXT FORMULA IS TRUE

=(MOD(LEFT(TEXT(A1;"00");1);2) + MOD(RIGHT(TEXT(A1;"00");1);2))=2

WHEN THE TWO DIGITS ARE EVEN THE NEXT FORMULA IS TRUE

=AND(A1<>"";(MOD(LEFT(TEXT(A1;"00");1);2) + MOD(RIGHT(TEXT(A1;"00");1);2))=0)

Use them accordingly. Change the ; with , according your local settings.
I modify the even formula to return FALSE on empty cells and remain without color. The formulas don't returm error on empty cells.

A second approach: (If cell is empty both return false)

true if digits are odd:

=MOD(INT(A1/10);2)+MOD(A1;2)=2

true if digits are even:

=AND(A1<>"";MOD(INT(A1/10);2)+MOD(A1;2)=0)