Compile value from each workbook to main workbook

I have multiple workbooks for each date e.g. Workbook_20230505 with format as below:

I am able to obtain latest time given a criteria using the formula =MAXIFS(B3:B13, C3:C13, "<>SYSTEM", C3:C13, "<>VOID")

How do I compile the result in a main file as below?

I tried using the below, but it seems hard to make it dynamic:

ActiveSheet.Range("B2").Select
ActiveCell.FormulaR1C1 = _
    "=MAXIFS([Workbook_20230505.xlsx]Sheet1!R3C2:R13C2,[Workbook_20230505.xlsx]Sheet1!R3C4:R13C4,""<>SYSTEM"",[Workbook_20230505.xlsx]Sheet1!R3C4:R13C4,""<>VOID"")"

I am also trying something as below, however, I am obtaining error:

strPath = "C:\Users\...\Workbook_20230505.xlsx"
Set wb = Workbooks.Open(strPath)
Set ws = wb.Worksheets("Sheet1")
Set sheet = ActiveSheet
Set rng1 = ws.Range("B3:B13")
Set rng2 = ws.Range("C3:C13")

sheet.Range("B2").Select
'ActiveCell.FormulaR1C1 = _
    '"=MAXIFS(rng1, rng2, "<>SYStem", rng2, "<>VOID")"

Ultimately, I want to use a for loop to obtain results for each date.

Appreciate the help!

Instead of using WorksheetFunction.MaxIfs, you can get the desired result using a For loop.

Sub GetMax()
    Dim FolderPath As String
    Dim FileName As String
    Dim wb As Workbook
    Dim ws As Worksheet
    Dim MaxValue As Date
    Dim DatePart As String
    Dim LastRow As Long
    Dim arr
    Application.ScreenUpdating = False
    ' Update your folder name
    FolderPath = "D:\Temp\"
    ' Clean activesheet and set format
    With ActiveSheet
        .UsedRange.Clear
        .[A1:B1].Value = Array("Date", "LatestTime")
        .Columns(1).NumberFormat = "mm/dd/yyyy"
        .Columns(2).NumberFormat = "h:mm:ss AM/PM"
    End With
    ' Retrieve files with "Workbook_*.xlsx"
    FileName = Dir(FolderPath & "Workbook_*.xlsx")
    Do While FileName <> ""
        DatePart = Split(FileName, "_")(1)
        Set wb = Workbooks.Open(FolderPath & FileName)
        Set ws = wb.Sheets(1)
        ' Get max value of column B
        arr = ws.UsedRange.Value
        MaxValue = 0
        If UBound(arr, 2) >= 3 Then
        For i = 2 To UBound(arr)
            If InStr("SYSTEM|VOID", UCase(arr(i, 3))) = 0 Then
                If MaxValue < arr(i, 2) Then MaxValue = arr(i, 2)
            End If
        Next
        End If
        wb.Close SaveChanges:=False
        With ThisWorkbook.Sheets(1)
            LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
            If LastRow > 1 Or .Cells(LastRow, 1) <> "" Then LastRow = LastRow + 1
            .Cells(LastRow, "A").Value = DateSerial(CInt(Mid(DatePart, 1, 4)), CInt(Mid(DatePart, 5, 2)), CInt(Mid(DatePart, 7, 2)))
            .Cells(LastRow, "B").Value = MaxValue
        End With
        FileName = Dir
    Loop
    Application.ScreenUpdating = True
End Sub