Sorting by alternate numbered rows without losing data

I want to sort by Sr.No. in ascending order in such a way that I get both Name and ID in the same order.Since the ID has no numbering alongside I am facing difficulty in doing so, can anyone please help

in Microsoft 365 you could use:
=SORTBY(WRAPROWS(B2:B9,2),TOCOL(A2:A9,1))
or:

=LET(a,A2:B9,
SORTBY(WRAPROWS(DROP(a,,1),2),TOCOL(TAKE(a,,1),1)))

Or if you want them stacked the way they were:

=LET(a,A2:B9,
TOCOL(SORTBY(WRAPROWS(DROP(a,,1),2),TOCOL(TAKE(a,,1),1))))

In older Excel you could use the following formula (dragged down/left):

=IFERROR(INDEX($B$2:$B$9,
               MATCH(SMALL($A$2:$A$9,ROW(A1)),
                     $A$2:$A$9,
                     0)
               +COLUMN(A1)-1),
         "")

or stacked (dragged down):

=IFERROR(INDEX($B$2:$B$9,
               MATCH(SMALL($A$2:$A$9,INT((1+ROW(A1))/2)),
                     $A$2:$A$9,
                     0)
               +ISEVEN(ROW(A1))),
         "")

P.b's answer is so elegant I can't compete.

But just for the record I took the question as requiring each person's data to be kept on two rows so came up with this:

=LET(range,A2:B9,
ser,INDEX(range,,1),
fill,SCAN(0,ser,LAMBDA(a,c,IF(c="",a,c))),
sort,SORTBY(range,fill),
IF(sort="","",sort))

Sort By Every Other Row

Add a helper column with the following formula in the first cell (row 2)...

=IF(MOD(ROW(),2),C1+1,2*A2-1)

... and copy down.

Now sort this column instead.

Edit

Here's another way to spill the sorted data in another place:

=LET(data,A2:B13,iCol,1,
    i,INDEX(data,,iCol),
    f,IF(i>0,2*i-1,0),
    s,VSTACK(0,DROP(IF(f>0,f+1,0),-1)),
SORTBY(IF(data="","",data),f+s))