Iterator not being reset at top of loop

For some context, this references the 2016 version of Excel. This is the only sub in the module.

Hello, I've been having a problem where running VBA script that used to work (for the same version) that now causes Excel to crash upon running. An interesting twist is that the same macro function works on the same workbook for other users but not for me. After some debugging, I identified which line was causing the crash and fixed the problem, but I am still wondering why the problem happened in the first place.

Sub graphing_name()
For each ws In ActiveWorkbook.Worksheets
   With ws
      for n = 1 To 10
         If .ChartObjects("Chart " & n).Chart.SeriesCollection.Count > 0 Then
            For s = 1 To .ChartObjects("Chart " & n).Chart.SeriesCollection.Count
               With .ChartObjects("Chart " & n).Chart.SeriesCollection(s)
                   .Format.Line.Weight = 2.25
               End With
            Next s
         End If
      Next n
   End With
Next ws
End Sub

When n = 2, the code was crashing on the .Format line. In the debugger, the value for s when this happened was 12 even though .ChartObjects("Chart " & n).Chart.SeriesCollection.Count = 11. Presumably, the crash was happening because Excel was trying to format a series line that doesn't exist.

Adding s = 1 in the line before the for statement solved the problem, but I have no idea why s was not being reset to 1 at the top of the For loop.

Could anyone explain why this happened and how I might be able to prevent this in the future?

Declare all variables, in your case they are all local variables. Try using ws.ChartObjects("Chart " & n).Chart once. I've run into a similar case where "Chart" & n didn't always produce the same result but converting n to string also put some extra space so it didn't find the object...

Sub graphing_name()
   Dim ws As Worksheet, n As Long, s As Long
   For Each ws In ThisWorkbook.Worksheets
      For n = 1 To 10
         ' use Trim for safety 
         With ws.ChartObjects("Chart " & Trim(n)).Chart
            If .SeriesCollection.Count > 0 Then
               For s = 1 To .SeriesCollection.Count
                  .SeriesCollection(s).Format.Line.Weight = 2.25
               Next
            End If
         End With
      Next
   Next ws
End Sub

You must be sure that the name of the ChartObject is exactly "Chart 2".
Or you can use error checking...

Sub graphing_name()
   Dim ws As Worksheet, n As Long, s As Long, cho As Object
   On Error Resume Next
   For Each ws In ThisWorkbook.Worksheets
      For n = 1 To 10
         Set cho = Nothing
         ' use Trim for safety
         Set cho = ws.ChartObjects("Chart " & Trim(n))
         If cho Is Nothing Then
            MsgBox ("Cannot find " & """Chart " & Trim(n) & """")
         Else
            With cho.Chart
               If .SeriesCollection.Count > 0 Then
                  For s = 1 To .SeriesCollection.Count
                     .SeriesCollection(s).Format.Line.Weight = 2.25
                  Next
               End If
            End With
         End If
      Next
   Next ws
   On Error GoTo 0
End Sub