Excel - count days in each month between two dates excluding weekends

I am trying to write an excel formula which can be dragged across a row of cells to give the number of days in each month between two specified dates. E.g:

1  | START DATE | END DATE  |  May  |  Jun  |  Jul  |  Aug  |...
   ---------------------------------------------------------
2  |  28/06/23  | 04/07/123 |   0   |  3    |  2    |   0   |...

I have this so far:

=MAX(0,MIN(IF($B2="",TODAY(),$B2),EOMONTH(DATEVALUE(C$1&"-23"),0))-MAX($A2,DATEVALUE(C$1&"-23"))+1)

Which gives this output:

image of ouput

Is there any way to alter this in order to exclude weekends?

Credits to Tom Sharpe.

You can generate the dates that represent the month (start of the month as follows) and put in on cell C1. It is an array formula, so no need to drag it to the right:

=EDATE(DATE(YEAR(A2),1,1), SEQUENCE(,12,0))

Now to calculate the working dates you can use NETWORKDAYS function as @P.b pointed out in the comment, checking first for the condition when two date intervals overlap:

=IF(AND(C1<=$B2,EOMONTH(C1,0)>=$A2), 
 NETWORKDAYS(MAX(C1,$A2), MIN(EOMONTH(C1,0),$B2)),0)

Put the formula in C2 and drag the formula to the right. Here is the output:

This is the condition to check for two intervals A,B overlap:

AND(startA <= endB, endA >= startB)

In C2 you can use an array solution too, via MAP function for example. We use LET function for easy reading and composition:

=LET(SOM,C1:N1, EOM,EOMONTH(1*SOM,0), startP,A2, endP,B2, 
 olaps,(SOM <= endP) * (EOM >= startP),
 MAP(olaps,SOM,EOM,LAMBDA(o,s,e,IF(o=0,0,
  NETWORKDAYS(MAX(startP,s),MIN(endP,e))))))

so, there is no need to extend the formula to the right. EOMONTH gives an error when using a range, so we use the following trick 1*SOM to convert it to an array to make it works.