How do I assign a new variable to each result in a For loop?

I am trying to search a column (H) for values, and if there are values, return the value in column C and assign it to a variable.

I would like to use a For loop to search for results (the column is mostly blank). Where there is a result, I want to create a new variable for each one, for later use. There will never be more than 5 results.
This is what I've tried, but putting together the variable name is not working for me.

Dim xDat1 As String
Dim XDat2 As String
Dim xDat3 As String
Dim xDat4 As String
Dim xDat5 As String

d = 1
For i = 186 To 235
If Not wsElog2.Range("H" & i) Is Nothing Then
    'get result from column C, and assign to a variable (xDat + the d value).
    xDat & d = wsElog2.Range("C" & i).Text
    'the above is showing red error - not sure how to put xDat and d together
End If
d = d + 1
Next i

Your main problem is the line

   If Not wsElog2.Range("H" & i) Is Nothing Then

which does not check if the respective cell is empty... Is Nothing should be used only for objects and you try checking the value of an object (a Range), which will always NOT be Nothing.

The second problem is that you cannot build the variable name by concatenation...

So, please, test the next adapted code. It will use a Scripting.Dictionar able to keep as many variables you need:

Sub testUseVariables()
   Dim wsElog2 As Worksheet, i As Long, dict As Object

    Set wsElog2 = ActiveSheet 'please, use the necessary sheet

    Set dict = CreateObject("Scripting.Dictionary")
    For i = 186 To 235
        If wsElog2.Range("H" & i).Value <> "" Then
            dict("H" & i) = wsElog2.Range("C" & i).text 'I used Text only because you wonted that.
                                                        'but, if the cell/column is not AutoFit, it will return only what you can see!
        End If
    Next i
    'you can test the result in the next way:
    If dict.count > 0 Then
        Debug.Print Join(dict.keys, "|")     'just to see where from the it comes (in H:H)
        Debug.Print Join(dict.Items, "|")    'the returned result
        Debug.Print dict.keys()(0), dict.keys()(1) 'a way of returning the item of a specific key number
    End If
End Sub

The next version is able to simulate the way of building the variables, but now, being a string, it works:

Sub testUseVars()
   Dim wsElog2 As Worksheet, d As Long, i As Long, dict As Object
   Const xD As String = "xDat"
   
    Set wsElog2 = ActiveSheet 'please, use the necessary sheet
    
    Set dict = CreateObject("Scripting.Dictionary")
    For i = 186 To 235
        If wsElog2.Range("H" & i).Value <> "" Then
            d = d + 1
            dict(xD & d) = wsElog2.Range("C" & i).text 'I would suggest using Value instead of Text...
        End If
    Next i

    'you can test the result in the next way:
    If dict.count > 0 Then
        Debug.Print Join(dict.keys, "|")     'just to see where from the it comes (in H:H)
        Debug.Print Join(dict.Items, "|")    'the returned result
        Debug.Print dict("xDat1"), dict("xDat2") 'a way of returning the item for a specific key
    End If
End Sub

Use an Array Instead of Many Numbered Variables

A Quick Fix (For...Next)

<!-- language: lang-vb -->

Sub Test()
Dim rCount As Long: rCount = 235 - 186 + 1
Dim dArr() As String: ReDim dArr(1 To rCount)
Dim i As Long, dCount As Long
For i = 186 To 235
If Len(CStr(wsELog2.Range("H" & i).Value)) > 0 Then
dCount = dCount + 1
'get result from column C, and assign to a variable (xDat + the dCount value).
dArr(dCount) = CStr(wsELog2.Range("C" & i).Value)
'the above is showing red error - not sure how to put xDat and dCount together
End If
Next i
' Check if all lookup cells were blank.
If dCount = 0 Then
MsgBox "All lookup cells were blank.", vbCritical
Exit Sub
End If
' Check if any blanks were found.
If dCount < rCount Then ' not all lookup cells were not blank
ReDim Preserve dArr(1 To dCount) ' resize the array
'Else ' all lookup cells were not blank; do nothing
End If
' Continue using the array...
' Return the comma-separated results in the Immediate window (Ctrl+G).
Debug.Print Join(dArr, ", ")
Dim d As Long
' Loop through the results and return one per row
' in the Immediate window.
For d = 1 To dCount
Debug.Print dArr(d)
Next d
End Sub

In More Detail: A Complete Example (For Each...Next)

<!-- language: lang-vb -->

Sub MatchesToArray()
' Reference the workbook and the worksheet.
Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
Dim ws As Worksheet: Set ws = wb.Sheets("ELog2") ' adjust!
' Reference the (same-sized) single-column ranges.
Dim lrg As Range: Set lrg = ws.Range("H186:H235") ' Lookup Range
Dim rrg As Range: Set rrg = lrg.EntireRow.Columns("C") ' Return Range
' Write the number of rows to a variable.
Dim rCount As Long: rCount = rrg.Rows.Count ' or lrg.Rows.Count
' Define a 1D one-based array of the same size as there are rows.
Dim dArr() As Variant: ReDim dArr(1 To rCount)
Dim lCell As Range, r As Long, dCount As Long
' Loop through the cells of the lookup range.
For Each lCell In lrg.Cells
r = r + 1 ' current (lookup/return) row index
' Check if the lookup cell is not blank.
If Len(CStr(lCell.Value)) > 0 Then ' the lookup cell is not blank
' Write the value from the current row index of the return range
' to the next (current) element of the array.
dCount = dCount + 1
dArr(dCount) = rrg.Cells(r).Value
'Else ' the lookup cell is blank; do nothing
End If
Next lCell
' Check if all lookup cells were blank.
If dCount = 0 Then
MsgBox "All lookup cells were blank.", vbCritical
Exit Sub
End If
' Check if any blanks were found.
If dCount < rCount Then ' not all lookup cells were not blank
ReDim Preserve dArr(1 To dCount) ' resize the array
'Else ' all lookup cells were not blank; do nothing
End If
' Continue using the array...
' Return the comma-separated results in the Immediate window (Ctrl+G).
Debug.Print Join(dArr, ", ")
Dim d As Long
' Loop through the results and return one per row
' in the Immediate window.
For d = 1 To dCount
Debug.Print dArr(d)
Next d
End Sub

Results

1, 5, 7, 10, 13
1 
5 
7 
10 
13 

The simple answer, if you know there are no more than 5, is to use an array, like this:

Dim xDats(5) As String
Dim d = 1
For i = 186 To 235
If Not wsElog2.Range("H" & i) Is Nothing Then
'get result from column C, and assign to a variable (xDat + the d value).
xDats(d) = wsElog2.Range("C" & i).Text
'the above is showing red error - not sure how to put xDat and d together
d += 1
End If
Next i

However, it is probably better to use a List(Of String) as this would give you slightly cleaner code and will eliminate an error in the situation where there are more than 5.

Dim xDats As New List(Of String)
For i = 186 To 235
If Not wsElog2.Range("H" & i) Is Nothing Then
'get result from column C, and assign to a variable (xDat + the d value).
xDats.Add(wsElog2.Range("C" & i).Text)
'the above is showing red error - not sure how to put xDat and d together
End If
Next i