variant changes when I pass it to function

A call to a Subroutine in VBA can be done either with

copyWiederkehrend wRows

or with

Call copyWiederkehrend(wRows)

Both commands are identically (some state that it is deprecated to use Call, but that's a different story).
If you call a Function and you are not interested in the result that is returned, the syntax is exactly the same. If you want to get the result of the function, syntax is

x = copyWiederkehrend(wRows)

But when you write

copyWiederkehrend (wRows)

the parenthesis around (wRows) are not used to show the VBA runtime the list of parameters. They are interpreted as "get the value of" (note that now a space is between the function name and the rest of the command).

Writing a statement like x = 3 * (y + 2) will do something similar: The runtime will calculate y + 2 and put this intermediate result somewhere into the memory, multiply it by 3 and ultimately pass this result to x. The point is that once the intermediate result is calculated, it is no longer associated with y. The same happens when you write x = 3 * (y) - the intermediate result contains the same value as y, but it is a copy of that value.

You can check this by passing a variable as parameter to a function by reference and then modify the value within the subroutine:

Sub Test()
    Dim v As Long
    v = 3
    testSub v
    Debug.Print v   ' This will print 4
    
    v = 3
    testSub (v)
    Debug.Print v   ' This will print 3
End Sub

Sub testSub(ByRef x As Long)
    x = x + 1
End Sub

In the first case, the value of v changed (because it was passed by reference). In the second case, an intermediate copy of v was passed and modified.

Now putting a Range into parenthesis will do something unusual: It will use the Default property of the Range object. You often see statements like x = Range("A1") in VBA (for Excel), and you don't think about it - you take it for granted that x will receive the Value of the cell A1. But if you think about it, it is not really easy to see what goes on. Range("A1") is an object of type Range with lots of properties, so why is the value assigned to x (and not, for example, the color, the width, the font size or number format)? This is because in VBA objects can have default properties that are used if you don't specify something: Writing x = Range("A1") is similar to x = Range("A1").Value.

So if your range wRowscontains only one cell, (wRows) will create a single value that then is passed as parameter. If it contains more than one cell, it will create a 2-dimensional array of values - that is what you see in your case in the debugger. Again, note that those values are no longer associated with the range, so if you modify them in the subroutine, they will not be written back into Excel.

One hint: As long as your work with Ranges (and not with the values stored in that range), you should declare your variables as Range, not as Variant.

Dim wRows As Range
Set wRows = ActiveSheet.range("B9:l7000").Rows.SpecialCells(xlCellTypeVisible) 

copyWiederkehrend wRows     ' This is okay
copyWiederkehrend (wRows)   ' Will throw an error.

Public Function copyWiederkehrend(all As Range)
    MsgBox ("HALLLLO")
End Function

Why this is throwing an error? Because (wRows) will create 2-dimensional array of values, and that is no longer a Range and therefore an error occurs (in this case "424- Object is required). Don't avoid this errors by converting everything to Variant - basically the runtime tells you that you did something wrong and that's a good thing.