Conditionally calculate difference between two columns on a sheet

I have a sheet allocations dynamically capturing data:

• A widget ID
• B email of tester 1 assigned to the widget
• D widget rating by tester 1
• E email of tester 2 assigned to the widget
• G widget rating by tester 2
• I Differences in the ratings

(columns C, F, H are email sent flags, so irrelevant for now)

What I want to happen

In column I, I want Excel to calculate the difference between columns D and G, but only if both columns D and G have numerical values.

Sample output:

Not this
Because I want column I to remain empty if not both of D and G have numerical values, and because I don't know upfront how many rows the sheet will end up having, I don't want to do something like =ABS(G2-D2) and copy it over all the way down.

Using MAP() and ISNUMBER() to check whether the values in columns D & G are numberic or not.

• Formula used in cell I2

=MAP(D2:D6,G2:G6,LAMBDA(x,y,IF(ISNUMBER(x)*ISNUMBER(y),ABS(y-x),"")))

Also, LAMBDA() iteration is not required if you are in MS365

• Formula used in cell I2

=LET(
       a,D2:D6,
       b,G2:G6,
       IF(ISNUMBER(a)*ISNUMBER(b),ABS(b-a),""))

Assuming Column A will have entries till last row, then you could use the following formula.

=LET(
       a,MATCH(7^89,A:A),
       b,D2:INDEX(D:D,a),
       c,G2:INDEX(G:G,a),
       IF(ISNUMBER(b)*ISNUMBER(c),ABS(c-b),""))

Or,

=LET(
       a,LOOKUP(2,1/(A:A<>""),ROW(A:A)),
       b,D2:INDEX(D:D,a),
       c,G2:INDEX(G:G,a),
       IF(ISNUMBER(b)*ISNUMBER(c),ABS(c-b),""))

Or,

=LET(
       b,DROP(FILTER(D:D,A:A<>""),1),
       c,DROP(FILTER(G:G,A:A<>""),1),
       IF(ISNUMBER(b)*ISNUMBER(c),ABS(c-b),""))