How to refer a variate with correct form in Kdb+?

I am using cli of Q. I found there are always 2 ways to refer a variable amid the context, as the belowing codes:

q)p:`AAPL`AAPL`GE`IBM`GE`IBM`GE`GOOG`GE`IBM`AAPL
q)x:`u#distinct p / apply the unique attribute
q)e:`x$p

At the 3rd line, x and p both refer to a table variate, but in the call of $(enumeration), it is required to use `x (as a symbol) to refer the related table, while use p directly (without back quote) to refer the other.

When shoudl I use the name with a back quote prefixed, and when not?

The exact answer will depend on the operation, since different operators accept different types. Enumeration in particular requires a symbol in its left argument and a symbol list in the right one. The fact that the symbol contains the name of a variable is part of the preconditions of the operator. In fact you could use a variable on the left side (x$p) but that would only work if the variable x contained a symbol, and then the variable named by that symbol would be the enumeration domain.

Other places where the usage of symbols is significant are table modifying operations (e.g. update, delete and xkey). If you provide the variable name, that counts as an expression and you get the modified table without the original variable being modified. On the other hand if you provide a symbol, it counts as a name and the variable with that name will be updated.

It depends based on the operations you are performing.

The https://code.kx.com/q website can guide you on when to use `

Including documentation on enumeration.

` prefixing the variable name can generally be seen to be used when the language wants to reference a global object rather than using it's value.

A good example where the ` can be used or not to give different meaning to your code is https://code.kx.com/q/ref/update/

q)t:([] a:1 2 3)
q)update a+1 from t //Perform an update and return the updated table
a
-
2
3
4
q)t2:update a+1 from t //Perform an update and store the result in t2
q)t2 
a
-
2
3
4
q)t //The global t table remains independent and unchanged
a
-
1
2
3
q)update a+1 from `t //Perform an in-place update to the global t variable
`t
q)t //t has been updated
a
-
2
3
4

One additional example which is relevant to enumeration:

q)s:`a`b`c

/using "?" and referencing the object by value results in a "find" (index lookup)
q)s?`c`d`b`a
2 3 1 0

/using "?" and referencing the object by name results in an enum-extend (enumeration, extending the enumeration list if required). 
q)`s?`c`d`b`a
`s$`c`d`b`a

/"d" was added to the enumeration domain
q)s
`a`b`c`d

Ultimately these overloaded operations are what allows kdb to perform many operations on a limited character list. The interpreter recognises the different overloads.