Adding values from different rows to VBA collection

I'm hoping someone with more VBA knowledge than me can teach me how to adjust my code to get the outcome I'm looking for. Let me start with the data I'll be using:

And current code (Class Module):

Public Key As String
Public SKU1 As String
Public Quantity1 As Long
Public SKU2 As String
Public Quantity2 As Long
Public SKU3 As String
Public Quantity3 As Long
Public SKU4 As String
Public Quantity4 As Long
Public SKU5 As String
Public Quantity5 As Long
Public ItemList As Collection
Private Sub Class_Initialize()
    SKU1 = 0
    Quantity1 = 0
    SKU2 = 0
    Quantity2 = 0
    SKU3 = 0
    Quantity3 = 0
    SKU4 = 0
    Quantity4 = 0
    SKU5 = 0
    Quantity5 = 0
    Set ItemList = New Collection
End Sub

(Module)

Public Sub POClass()

Dim col As Collection
Dim dataItems As cItems
Dim itemKey As String
Dim item1 As String
Dim item2 As Long
Dim ws As Worksheet
Dim r As Long

Set ws = ActiveSheet
Set col = New Collection

Dim lastRow As Long
lastRow = ws.Cells(Rows.Count, "A").End(xlUp).Row

For r = 2 To lastRow
    itemKey = CStr(ws.Cells(r, "A").Value2)
    item1 = CStr(ws.Cells(r, "M").Value2)
    item2 = CLng(ws.Cells(r, "N").Value2)

    'Check if key already exists
    Set dataItems = Nothing: On Error Resume Next
    Set dataItems = col(itemKey): On Error GoTo 0

    'If key doesn't exist, create a new class object
    If dataItems Is Nothing Then
        Set dataItems = New cItems
        dataItems.Key = itemKey
        col.Add dataItems, itemKey
    End If

    'Add cell values to the class object
    With dataItems
        .SKU = item1
        .Quantity = item2
        .ItemList.Add item1
        .ItemList.Add item2
    End With

Next

End Sub

Essentially, I'm trying to have the macro go through each row and do the following:

1. Add PO Number to the collection
2. Add each Vendor Item# and Qty to the corresponding PO Number
3. Store each Vendor Item# and Qty in SKU1-5 and Quantity 1-5

Each PO might have as little as 1 item or up to 5. Am I doing this correctly or is there a better way? I can't figure out how to get SKUs/Quantities added to the same PO number if there are multiple for one PO.

So the expected output would be:

Key: MO-0021244
SKU1: NFLPACK8D
Quantity1: 1
SKU2: NFLPACK9D
Quantity2: 1

Key: MO-008512
SKU1: NFLPACK8M
Quantity1: 1

Key: MO-965403
SKU1: NFLPACK9
Quantity1: 1

Key: MO-780066
SKU1: SOCLAM1
Quantity1: 1

You could use a dictionary instead of a collection to make it easier to store the SKU and quantities together and this approach scales better when you have a lot of possible values. You completely avoid having to define variables with an index (Quantity1, Quantity2, Quantity3, etc.).

Your class module would then be:

Public Key As String
Public ItemList As Dictionary 'Requires Microsoft Scripting Runtime Library (Tools > References... > Add "Microsoft Scripting Runtime" > Press OK)
Private Sub Class_Initialize()
    Set ItemList = New Dictionary
End Sub

Which would give you this data structure (class diagram):

Then, in your code module, you'd replace :

    'Add cell values to the class object
    With dataItems
        .sku = item1
        .Quantity = item2
        .ItemList.Add item1
        .ItemList.Add item2
    End With

with

    'Add cell values to the class object
    dataItems.ItemList.Add item1, item2

Then you can loop over the values and return the output you mentioned in your quesiton like this :

Dim cItem As cItems
For Each cItem In col
    
    Dim qtyDetails As String
    qtyDetails = vbNullString

    Dim sku As Variant
    For Each sku In cItem.ItemList.Keys
        qtyDetails = qtyDetails & " SKU: " & sku & " Quantity: " & cItem.ItemList(sku)
    Next sku

    Debug.Print "Key: " & cItem.Key & " " & qtyDetails

Next

Also note that you could avoid using a class and use a nested dictionary instead.