Highlight multiple table row only instead of entire row

Is there a way to only highlight multiple active cell rows only within the table range instead of the entire sheet row?
I have tried conditional formatting but it does not work for multiple active cell selection.

Here is my current working code. Thank you

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Application.ScreenUpdating = False

With Target
  EntireRow.Interior.ColorIndex = 36
End With

Application.ScreenUpdating = True

End Sub

I recommend the following:

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim Table As ListObject
    Set Table = Target.ListObject
    
    If Not Table Is Nothing Then
        Dim ColorRange As Range
        Set ColorRange = Application.Intersect(Table.DataBodyRange, Target.EntireRow)
        If Not ColorRange Is Nothing Then
            ColorRange.Interior.ColorIndex = 36
        End If
    End If
End Sub

Target.ListObject will point to the table of the selected cell without having to hard code the tables name. Also if you Intersect with Table.DataBodyRange it does not color the headline of the table but only the data range. Using Intersect it is always recommended to check if the two ranges intersected at all If Not ColorRange Is Nothing Then before using them, otherwise you easily run into errors.

Note that with the code above it will add colored rows to the table.

If you want to color only the currently selected row then use the code below:

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim Table As ListObject
    Set Table = Target.ListObject
    
    If Not Table Is Nothing Then
        ' decolorize prevously colored rows
        With Table.DataBodyRange.Interior
            .Pattern = xlNone
            .TintAndShade = 0
            .PatternTintAndShade = 0
        End With
        
        Dim ColorRange As Range
        Set ColorRange = Application.Intersect(Table.DataBodyRange, Target.EntireRow)
        If Not ColorRange Is Nothing Then
            ColorRange.Interior.ColorIndex = 36
        End If
    End If
End Sub

Highlight Table Rows of Selected Table Cell

• In the screenshot, the cells were selected using <kbd>Ctrl</kbd>+<kbd>Right-Click</kbd>.

<!-- language: lang-vb -->

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Const CLEAR_EXISTING_HIGHLIGHTS As Boolean = True

    ' Reference the table's data range (exclude headers).
    
    Dim trg As Range, rCount As Long
    
    ' For a table (not Excel (structured) table) starting in cell 'A1':
    With Me.Range("A1").CurrentRegion
        rCount = .Rows.Count - 1
        If rCount = 0 Then Exit Sub ' no data
        Set trg = .Resize(rCount).Offset(1)
    End With
    
    ' For an Excel (structured) table:
'    With Me.ListObjects("Table1")
'        If .DataBodyRange Is Nothing Then Exit Sub ' empty table
'        Set trg = .DataBodyRange
'    End With

    ' Consider only cells in the table's data range.
    
    Dim irg As Range: Set irg = Intersect(trg, Target)
    If irg Is Nothing Then Exit Sub
    
    ' Clear existing highlights.
    
    If CLEAR_EXISTING_HIGHLIGHTS Then
        trg.Interior.ColorIndex = xlNone
    End If
    
    ' Apply new highlights.
    
    Set irg = Intersect(trg, irg.EntireRow)
    irg.Interior.ColorIndex = 36

End Sub

One method is to get the intersection of your selected rows and your table. Replace "Table1" with the name of your table.

I have also added a suggestion if you want to clear the color from your previous selection.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Application.ScreenUpdating = False

'ActiveSheet.UsedRange.Interior.ColorIndex = 0  'Use this if you want to clear the color from your previous selection first

With Target
  Intersect(ListObjects("Table1").Range, .EntireRow).Interior.ColorIndex = 36
End With

Application.ScreenUpdating = True

End Sub