How do I write a formula in excel that lists a value contained in one cell for each incremental number value contained in another cell?

I have a cell that contains csv data (Cell A). I have another cell that contains a quantity value (Cell B). I would like a formula that lists the Cell A for each incremental value contained in Cell B.

I have tried searching for related topics with no similar results.

An example of how I would like it to function:

Cell A is DataCell 
B is 5,
Column C:C (Formula) is Data,
spill into next row in C:C is Data,
spill into next row in C:C is Data,
spill into next row in C:C is Data,
spill into next row in C:C is Data

Based on your comments, I think I understand what it is you are after. You wish to repeat a certain value n-times in seperate cells. The fact that it's a CSV-value is irrelevant here.

Formula in C1:

=INDEX(A1,SEQUENCE(B1,,,0))

Or better:

=EXPAND(A1,5,,A1)

If you just want it separated by newline character in the same row, then for C2 the formula would be

=IF(
  OR(
    A2 = "",
    B2 = "",
    B2 < 1
  ),
  "",
  A2 & IF(
    B2 < 2,
    "",
    REPT(
      CHAR(10) & A2,
      B2 - 1
    )
  )
)

If instead you want C2 to spill down, you can convert it into an array using TEXTSPLIT like @JrdV suggested, with an empty 2nd argument and using the 3rd argument to split into rows. So...

=IF(
  OR(
    A2 = "",
    B2 = "",
    B2 < 1
  ),
  "",
  TEXTSPLIT(
    A2 & IF(
      B2 < 2,
      "",
      REPT(
        CHAR(10) & A2,
        B2 - 1
      )
    ),
    ,
    CHAR(10)
  )
)

This assumes A2 doesn't contain any newline characters. If it does then you would have to use a delimiter other than CHAR(10), Perhaps "ç" or "§".