Macro to delete duplicate rows based on combination of two columns and a condition

Need help to create a macro to delete duplicate rows based on combination of two columns (year and LN columns). While removing the duplicate rows, only the rows having price 0 to be removed if price value in both rows are not same.

Sample data:

In my macro, I am not able to check for the condition "only the rows having price 0 to be removed if price value in both rows are not same".
Any guidance would be appreciated.

Please, use the next code. You should prove that made some researches by your own, at least mention that and problems you faced... There are many pieces of code treating the issue, only I posted some, but condition to delete the ones having zero in the fifth column may be something peculiar. So, I am making an exception, hoping that you know what is to be done if place a new question. The code assumes that the headers are on the first row and starts from "A:A" column.

Sub removeDuplicate3ColumnsCond()
  Dim sh As Worksheet, lastR As Long, arr, arrIt, i As Long, rngDel As Range, dict As Object
  
  Set sh = ActiveSheet 'use here the sheet you need
  lastR = sh.Range("A" & sh.rows.count).End(xlUp).row 'last row on column A:A
  arr = sh.Range("A1:E" & lastR).Value2 'place the range in an array for faster iteration
  
  Set dict = CreateObject("Scripting.Dictionary") 'set the necessary dictionary, to kepp only unique combinations
  For i = 2 To UBound(arr)
    If Not dict.Exists(arr(i, 1) & arr(i, 2)) Then
        dict.Add arr(i, 1) & arr(i, 2), Array(arr(i, 5), i) 'dictionary key as columns combination, item = Array(Price, row)
    Else
       If dict(arr(i, 1) & arr(i, 2))(0) = 0 Then           'if the price of the first occurrence is zero
           addToRange rngDel, sh.Range("A" & dict(arr(i, 1) & arr(i, 2))(1)) 'add the row to the range to be deleted
           arrIt = dict(arr(i, 1) & arr(i, 2))                                 'place the dictionary item in an array
           arrIt(1) = arr(i, 5): dict(arr(i, 1) & arr(i, 2)) = arrIt 'change the price and drop back the modified array
       Else
           addToRange rngDel, sh.Range("A" & i)      'place the row in the Union range to be deleted
       End If
    End If
  Next i
  
  'select the rows to be deleted, in order to visually check them:
  If Not rngDel Is Nothing Then rngDel.EntireRow.Select
  'if the selected rows are OK, replace `Select` from the above line with `Delete`
End Sub

Reading the above comments, I hope you understood that the code, as it is, only selects the rows to be deleted. If you like that selection, you should replace Select with Delete in the last code line.

You did not answer my clarification question and my code assumes that there can be more than two occurrences. It will delete the zero price (in column E:E) cases, but all cases related to price, except one, if no zero price exists, or it has already been placed in the range to be deleted.