Loop through rows of a table on outlook and change (Text To Display) to an ascending number per each row

I have used the below code to Loop through selection on outlook and convert into Hyperlinks and change Text To Display Link.
it works but it adds the the ascending number incrementally to all cells like this picture:

My need is to add the ascending number per each row like this picture:

In advance, great thanks for all your help.

Sub Hyperlink_Outlook()

  Dim wDoc As Word.Document, rngSel As Word.Selection, cel As Cell, i As Long
  
  Set wDoc = Application.ActiveInspector.WordEditor
  Set rngSel = wDoc.Windows(1).Selection
    
  If Not rngSel Is Nothing And rngSel.Information(wdWithInTable) Then
    If rngSel.Range.Cells.Count > 0 Then
       For Each cel In rngSel.Cells
         If Len(cel.Range.Text) > 10 Then
           i = i + 1
            wDoc.Hyperlinks.Add cel.Range, _
             Address:=Left(cel.Range.Text, Len(cel.Range.Text) - 1), _
             TextToDisplay:="Attachment " & i
         End If
       Next
    End If
  End If
  
End Sub

Try looping through rows first (the following is not tested):

Sub Hyperlink_Outlook()

  Dim wDoc As Word.Document, rngSel As Word.Selection, cel As Cell, i As Long
  Dim r As Variant
  
  Set wDoc = Application.ActiveInspector.WordEditor
  Set rngSel = wDoc.Windows(1).Selection
    
  If Not rngSel Is Nothing And rngSel.Information(wdWithInTable) Then
    If rngSel.Range.Cells.Count > 0 Then
      For Each r In rngSel.Rows
        i = 0 ' reset i here
        For Each cel In r.Cells
          If Len(cel.Range.Text) > 10 Then
            i = i + 1
             wDoc.Hyperlinks.Add cel.Range, _
              Address:=Left(cel.Range.Text, Len(cel.Range.Text) - 1), _
              TextToDisplay:="Attachment " & i
          End If
        Next cel
      Next r
    End If
  End If
  
End Sub

Please, try the next adapted code:

Sub Hyperlink_OutlookCols()
 'Columns in Excel must be autoFit
  Dim wDoc As Word.Document, rngSel As Word.Selection, cel As Word.Cell
  
  Set wDoc = Application.ActiveInspector.WordEditor
  Set rngSel = wDoc.Windows(1).Selection
    
  If Not rngSel Is Nothing And rngSel.Information(wdWithInTable) Then
    If rngSel.Range.Cells.count > 0 Then
       For Each cel In rngSel.Cells
          If Len(cel.Range.Text) > 10 Then
             wDoc.Hyperlinks.Add cel.Range, _
              Address:=Left(cel.Range.Text, Len(cel.Range.Text) - 1), _
                                         TextToDisplay:="Attachment " & cel.Column.Index
          End If
       Next cel
    End If
  End If
  
End Sub

You should copy the cells from Excel after autoFit the respective columns...