Function not using the right range in VBA

I am using a function I got from Excel tips to get the row of the first partial match of a name.

The idea of all this is to track holidays.
I have one special spreadsheet being used as a database where I store all the data. Every change made is stored in the data spreadsheet which in in our cloud. That is used to spread the data into other computers using copy paste to every workspaces sheet.

My issue is sometimes the function being used searches for the employee using the wrong range.

This is the function code:

Function FirstPartMatch(str As String, rng As Range)
Dim tmp As Long
Dim position As Long
Dim cll As Range

position = 0
tmp = 0

For Each cll In rng
    
    tmp = tmp + 1
    If InStr(1, LCase(cll.Value2), LCase(str)) > 0 Then
        
        position = tmp
        Exit For
    
    End If

Next cll

If position Then
    
    FirstPartMatch = position

Else
 
    FirstPartMatch = "#NA"

End If

End Function

Here is my code that we use to add holidays via a form:

Private Sub cmdOk_Click()
Dim name As String
Dim ws As Worksheet
Dim vdate As Date
Dim agency As String
Dim code As String
Dim lastrow As Long
Dim Rlastrow As Long
Dim holiday As Double

Application.ScreenUpdating = False

open_wb_onedrive 'open data file
Set ws = openwb.Worksheets("data") 'assign sheet of data file to variable

With ws
    
    .Unprotect Password:=pass
    lastrow = .Cells(Rows.Count, 22).End(xlUp).Row + 1 'finds first empty row of the holidays column
    Rlastrow = .Cells(Rows.Count, 1).End(xlUp).Row + 1 'finds the first empty row of the employee column
    
    'assign the imput data to variables
    name = Me.cmbName.value
    agency = Me.cmbPosition.value
    vdate = CDate(Me.cmbDate.value)
            
    'Checks if name is already in holiday column, and skips the code if it is
    If FirstPartMatch(name, .Range("V1:V" & lastrow)) > 0 Then
            
        MsgBox ("Holiday already exists")
        GoTo Skip
    
    Else
        
        'Adds data if new name on holiday list
        .Cells(lastrow, 22).value = name
        .Cells(lastrow, 23).value = vdate
        
        holiday = FirstPartMatch(name, .Range("A1:A" & Rlastrow)) 'finds in which row the employee is
        .Cells(holiday, 1).value = name & " Holiday until " & vdate 'ads the holiday info
        
    End If
    
    .Protect Password:=pass
    
End With

'end of sub code to close the data file
Skip:
get_data ws
Unload Me
End Sub

The issue on the code happens on this if part:

If FirstPartMatch(name, .Range("V1:V" & lastrow)) > 0 Then

Instead of searching on the data file in column V, the code does the search on my original file and sheet on column A. (where the code is being run)

I wonder where is my mistake as I don't reference the code spreadsheet or sheet in the whole code and just use it to display my data mirrored from my other file.

Code for open_wb_onedrive as requested:

Sub open_wb_onedrive()
   Dim wbFullName
   Set objLogExcel = CreateObject("Excel.Application")
   objLogExcel.Visible = True
   wbFullName = "https://onedrive_hidden_url/data.xlsx"
   Set openwb = objLogExcel.Workbooks.Open(wbFullName)
   
End Sub

Workaround found: (Still baffled why part of the previous code works and part doesn't)

'Checks if name is already in holiday column, and skips the code if it is
    If InStr(1, LCase(name), LCase("holiday")) <> 0 Then
            
        MsgBox ("Holiday already exists")
        GoTo Skip
    
    Else
        
        'In the case it's not adds the data to the table
        .Cells(lastrow, 22).value = name
        .Cells(lastrow, 23).value = vdate
        
        holiday = FirstPartMatch(name, .Range("A1:A" & Rlastrow)) 'finds in which row the employee is
        .Cells(holiday, 1).value = name & " Holiday until " & vdate 'ads the holiday info

Your openwb object is not available in the cmdOK_Click Sub. Place a

Dim openwb as Workbook

in the Declaration section of the module where the open_wb_onedrive Sub is.