Inserting Landscape file into VBA Combined Document changes Section Break

I have a Word VBA macro that combines Word documents in a file folder into a single combined file that puts each document in a new section and retains the header and footer of the original file. The code unprotects the source file, inserts a Section Break (Next Page) at the end of the Target file, transfers the page layout information from the source document to the new target section, then inserts the source file. The files contain tables with Word Content Controls which are in a protected section (Fill in forms). The end of the protected section contains a Section Break (Next Page) and then a table that is not protected and has no Content Controls.

The problem is if the source file is Landscape formatted the Section Break is converted from Next Page to Continuous. If I insert two Next Page breaks the second one is changed to continuous. Manually deleting the Continuous break changes all of the Next Page breaks to continuous. I'm using Word365. I have tried using both .InsertFile and .FormattedText but get the same result. I’ve researched extensively and am unable to find a fix that works.

Code section causing the problem

With DocTgt
      Set Rng = .Range.Characters.Last
      With Rng
        .Collapse wdCollapseEnd
         'Double section break required to prevent adding landscape files changing break 
         'from NextPage to Continuous
        .InsertBreak Type:=wdSectionBreakNextPage
        .InsertBreak Type:=wdSectionBreakNextPage 
       .Collapse wdCollapseEnd
        Call LayoutTransfer(DocSrc, DocTgt)
        '.FormattedText = DocSrc.Range.FormattedText
        .InsertFile FileName:=strFolder & "\" & strFile
      End With
...

I have tried using both .InsertFile and .FormattedText but get the same result. I was expecting the Landscape formatted documents to work the same as Portrait formatted ones.

I suspect that the issue is with the landscape file you are inserting. Open the file in Word and check the "Section start" setting on the Layout tab of the Page Setup dialog.

A normal document will have a value of "New page". If yours has a value of "Continuous" that will be the cause of the problem, which is very simple to fix:

Dim secIdx As Long
With DocTgt
    Set Rng = .Range.Characters.Last
    With Rng
        .Collapse wdCollapseEnd
        .InsertBreak Type:=wdSectionBreakNextPage
        .Collapse wdCollapseEnd
        'store section number so start type can be reset
        secIdx = .Information(wdActiveEndSectionNumber)
        Call LayoutTransfer(DocSrc, DocTgt)
        '.FormattedText = DocSrc.Range.FormattedText
        .InsertFile FileName:=strFolder & "\" & strFile
    End With
    'reset section start if necessary
    With .Sections(secIdx).PageSetup
        If .SectionStart = wdSectionContinuous Then .SectionStart = wdSectionNewPage
    End With
End With

As far as I know, all you need is to add an extra paragraph at the end of the rng, in case there are no extra empty paragraphs at the end of the source file to separate them so that the inserted subsection break mark can be displayed correctly, otherwise they will interfere with each other. The following is the code I tested, and the next page does not become a continuous page as you said again, the inserted result is the next page style section break.

Sub Inserting_Landscape_file_into_VBA_Combined_Document_changes_Section_Break()
    With DocTgt
      Set rng = .Range.Characters.Last
      With rng
        .Collapse wdCollapseEnd
         'Double section break required to prevent adding landscape files changing break
'         from NextPage to Continuous

        rem add these two lines into your code and remain the only one ".InsertBreak" statement is enough
        .InsertParagraphAfter
        .Collapse wdCollapseEnd


        .InsertBreak Type:=wdSectionBreakNextPage


        rem remain the only one ".InsertBreak" statement is enough
'        .InsertBreak Type:=wdSectionBreakNextPage


       .Collapse wdCollapseEnd
'        Call LayoutTransfer(DocSrc, DocTgt)
        '.FormattedText = DocSrc.Range.FormattedText
        .InsertFile FileName:=strFolder & "\" & strFile
      End With
    End With
End Sub