Find matching header, copy/paste value in last row

I want to copy data from a daily report, open another workbook(databank) if the column headers in both sheets match. then find last empty cell in row in matching header to paste data from the daily report, save, then close. I have pieced together a macro but I'm only just beginning to learn vba. I'm sure the structure and order is wrong.

Sub Submit()
Dim head_count As Integer
Dim row_count As Integer
Dim col_count As Integer
Dim i As Integer
Dim j As Integer
Dim wsCopy As Worksheet


Application.ScreenUpdating = False

Set wsCopy = ThisWorkbook.Sheets("DAILY REPORT")
head_count = WorksheetFunction.CountA(Range("A1", Range("A1").End(xlToRight)))


Workbooks.Open ("Y:\Daily_Yield&Production_Report.2\FREEPORT_PRO_YIELD_DAILY_REPORT\PLT-1-2-3_PYDR.xlsm")
ActiveWorkbook.Sheets("PLT-1").Activate

row_count = WorksheetFunction.CountA(Range("A1", Range("A1").End(xlDown)))
col_count = WorksheetFunction.CountA(Range("A1", Range("A1").End(xlToRight)))

For i = 1 To head_count

    j = 1
    
    Do While j <= col_count
    
        If wsCopy.Cells(1, i) = ActiveSheet.Cells(1, j).Text Then
        
            ActiveSheet.Range(Cells(1, j), Cells(row_count, j)).Copy
            
            wsCopy.Cells(1, i).PasteSpecial xlPasteValues
            Application.CutCopyMode = False
            j = col_count
            
        
        End If
        
    j = j + 1
    
    Loop
    
    
Next i

ActiveWorkbook.Close savechanges:=False

wsCopy.Cells(1, 1).Select
    
Application.ScreenUpdating = True
End Sub

I have youtubed for answers for the past week but im limited in knowledge on this topic.

Try this out - using Find() to match columns

Sub Submit()
    Dim c As Range, wsCopy As Worksheet, f As Range, wbData As Workbook, rngSource As Range

    Application.ScreenUpdating = False

    Set wsCopy = ThisWorkbook.Worksheets("DAILY REPORT")
    
    Set wbData = Workbooks.Open( _
       "Y:\Daily_Yield&Production_Report.2\FREEPORT_PRO_YIELD_DAILY_REPORT\PLT-1-2-3_PYDR.xlsm")
    Set rngSource = wbData.Worksheets("PLT-1").Range("A1").CurrentRegion
    
    For Each c In wsCopy.Range(wsCopy.Range("A1"), _
                                wsCopy.Cells(1, Columns.Count).End(xlToLeft)).Cells
        
        Set f = rngSource.Rows(1).Find(what:=c.Value, lookat:=xlWhole)
        If Not f Is Nothing Then 'matched column?
            With f.Offset(1).Resize(rngSource.Rows.Count - 1)
                c.Offset(1).Resize(.Rows.Count) = .Value 'assign values directly
            End With
        End If
                                
    Next c
    
    wbData.Close False
    wsCopy.Cells(1, 1).Select
    
    Application.ScreenUpdating = True
End Sub