Add the sum of array values to hash (map / grep)

I've been trying to figure out this one-liner, and can't seem to get it to work.

Say I have this reference to an array of hashrefs:

my $payments = [
   {
      'receipt_id'     => '100',
      'payment_id'     => '1',
      'payment_amount' => 20,
   },
   {
      'receipt_id'     => '100',
      'payment_id'     => '1',
      'payment_amount' => 30,
   },
   {
      'receipt_id'     => '100',
      'payment_id'     => '2',
      'payment_amount' => 40,
   },
   {
      'receipt_id'     => '200',
      'payment_id'     => '1',
      'payment_amount' => 20,
   },
];

What I'd like to do is create a hash where the key is the payment_id, and the value is the sum of all payment_amounts for a particular receipt_id.

I can do:

my %sum_payments = map  { $_->{payment_id} => $_->{payment_amount} }
                   grep { $_->{receipt_id} eq '100' }
                   @$payments;

And get:

1 => 30,
2 => 40,

But when I try:

my %sum_payments = map  { $_->{payment_id} => (sum map { $_->{payment_amount} }) }
                   grep { $_->{receipt_id} eq '100' }
                   @$payments;

It throws errors.

How can I write a one-liner using map / grep to get:

1 => 50,
2 => 40,

Also, I know there are many other ways to achieve the same thing. I'm interested to know if this is possible using a single statement with map / grep.

The problem with the approach you are trying is that to calculate the sum with a function like that requires you to somehow build up a list for each payment_id before you pass it to the function. It may be possible to do this all in one line, but I think it is much more straightforward to use a for loop in this case:

my %sum_payments;
for (@{ $payments }) {
    if ($_->{receipt_id} eq '100') {
        $sum_payments{ $_->{payment_id} } += $_->{payment_amount};        
    }
}

Output:

      '1' => 50,
      '2' => 40

You just need something to accumulate into - such as assigning directly into the destination hash:

my %sum_payments;

map { $sum_payments{$_->{payment_id}} += $_->{payment_amount} }
grep { $_->{receipt_id} eq '100' }
@$payments;

This is similar to @toolic's answer but, as that says, less readable (and I think less inefficient on large input due to grep building an intermediate list), and some people don't like map used like this.

I'm a bit unsure of the exact requirements but I take it that the complete result would be

payment_id      receipt_id     sum of amounts
1           =>  100        =>  50  (20+30)
                200        =>  20
2           =>  100        =>  40 

Then

my %recd;
for my $hr (@$payments) {
    $recd{$hr->{payment_id}}{$hr->{receipt_id}} += $hr->{payment_amount}
}

dd \%recd;  # w/ use Data::Dump;  Or use core Data::Dumper

Prints

{ 1 => { 100 => 50, 200 => 20 }, 2 => { 100 => 40 } }

For each id there are keys of all receipts, each having for a value the total amounts.

Still not sure why receipt_id of 100 is singled out in the question (and all answers) ... because the idea is that only one is needed in each run of the program? If that is so then this answer is an overkill; use some of the others.

On the other hand, it's plausible that there'll be further needs and why not build it with all data. Then the specific ones can be plucked out as needed, by a direct lookup.

The specific map+grep attempt from the question won't work because map in each iteration has one record (hashref) on hand so it can't simply sum up payment_amount across all of them.

So I think that no, one can't reasonably have that (other than by some bad acrobatics formally cast in a single statement eventually assigning to a hash, that is).