DataWeave 1.0 lower function is not working as expected

I have a below function that checks for the string and removes the value.
It works fine when the string matches the case accurately. I tried to add lower to check for both possibilities in a given string. but it is not working as expected.

If the payload contains a value from filterList it removes only the key and value that matches exactly as "phone". But, the expectation is to remove if key/value has "phone","Phone","secondaryPhone" etc

Input:

{
    "phone":"123-234-9872",
    "Type":"Phone",
    "aType": ["T1", "T2"]
}

Expected output:

{
    "aType": ["T1", "T2"]
}

Script:

%dw 1.0
%output application/json skipNullOn="everywhere"
     
%function remove(content, filterList)
        content match {
            :array -> $ map (value,index) -> remove(value, filterList),
            :object -> $ mapObject (value,key) ->
                (key): null when (filterList contains (lower key as :string))
                    otherwise remove(value, filterList)
                ,
            default -> null when ((content !=null) and (filterList contains content as :string)) otherwise content
        }
---
remove(payload,["phone","email","accountNumber"])

The problem is that the condition used for default doesn't include changing the case of the content. The condition is also a bit complex because the script is not using match to consider the case for when content is a string. Using the full power of pattern matching simplifies the evaluation.

%dw 1.0
%output application/json skipNullOn="everywhere"
     
%function remove(content, filterList)
        using (lowerFilters=filterList map (lower $)) (content match {
            :array -> $ map (value,index) -> remove(value, lowerFilters),
            :object -> $ mapObject (value,key) ->
                (key): null when (lowerFilters contains (lower key as :string))
                    otherwise remove(value, lowerFilters)
                ,
            :string -> null when (lowerFilters contains (lower content)) otherwise content,
            default -> content
        })

---
remove(payload,["phone","email","accountNumber"])

An additional improvement is to use a local variable that lowers also the items in filterList. For example "accountNumber" would not match even when the actual value is "accountnumber" in the original version.