How to remove an entry from JSON using dataweave?

I have a json like below:

{   "queueNumber": "123",   "field": "name",   "UserId": [     12,     12,     34   ],   "test": [     {       "objectName": "test",       "uniqueNumber": "123456"     }   ] }

I have a function which iterates over each key and removes it if matches. But, I also need to check for the value. I tried with the below function it works perfect when it comes to check and remove the key. But, it is giving an exception when I am checking for the value.

%dw 2.0
output application/json
var keyToRemove = "queueNumber|name|uniqueNumber|cur|UserId" splitBy  "|"
fun removePair(e, keyToRemove) =
e match {
case is Array  -> e map removePair($, keyToRemove)
case is Object -> e mapObject (v, k) ->
if (keyToRemove contains(k as String) or keyToRemove contains(v as String))
                         {}
else
                          {(k): removePair(v, keyToRemove)}
else           -> e
 }
---
removePair(payload, keyToRemove)

Error:
Cannot coerce String (queueNumber) to Boolean if (keyToRemove contains(k as String) or keyToRemove contains(v as String))

How to enhance this function to also check and remove if any one of the given fields matches the value?

Assuming, this is your input:

{
  "queueNumber": "123",
  "field": "name",
  "UserId": [
    12,
    12,
    34
  ],
  "test": [
    {
      "objectName": "test",
      "uniqueNumber": "123456"
    }
  ]
}

To remove a single property from an object the syntax is like this:

%dw 2.0
output application/json
---
payload -"field"

The result:

{
  "queueNumber": "123",
  "UserId": [
    12,
    12,
    34
  ],
  "test": [
    {
      "objectName": "test",
      "uniqueNumber": "123456"
    }
  ]
}

To remove multiple properties (array), this is the syntax:

%dw 2.0
output application/json
---
payload -- ["field", "test"]

The result:

{
  "queueNumber": "123",
  "UserId": [
    12,
    12,
    34
  ]
}

To remove a single nested property, it can be done like this:

%dw 2.0
output application/json
fun removePair(e, key) =
  e match {
    case is Array  -> e map removePair($, key)
    case is Object -> e mapObject (v, k) ->
                        if ((k as String) == key)
                          {}
                        else
                          {(k): removePair(v, key)}
    else           -> e
  }
---
removePair(payload , 'uniqueNumber')

The result:

{
  "queueNumber": "123",
  "field": "name",
  "UserId": [
    12,
    12,
    34
  ],
  "test": [
    {
      "objectName": "test"
    }
  ]
}

To remove multiple nested properties use this:

%dw 2.0
output application/json
fun removePair(e, key) =
  e match {
    case is Array  -> e map removePair($, key)
    case is Object -> e mapObject (v, k) ->
                        if (key contains (k as String))
                          {}
                        else
                          {(k): removePair(v, key)}
    else           -> e
  }
---
removePair(payload , ['uniqueNumber', "queueNumber"])

The result:

{
  "field": "name",
  "UserId": [
    12,
    12,
    34
  ],
  "test": [
    {
      "objectName": "test"
    }
  ]
}

There are several errors in the condition. First you should use parenthesis so the expression is evaluated in the correct order. Secondly -you haven't got yet this error because of the first one- you are trying to convert v to a String but when it is an array it is not possible to do that. So you should update the expression to something like:

case is Object -> e mapObject (v, k) -> if ((keyToRemove contains (k as String)) or ((v is String) and (keyToRemove contains (v as String))))

Having said that you may want to consider using filterObject() in your script to remove unwanted members. This makes the intention of the transformation clearer and easier to understand:

%dw 2.0
output application/json  

var keyToRemove = ["queueNumber","name","uniqueNumber","cur","UserId"]

fun removePair(e, keyToRemove) =
  e match {
    case is Array -> e map removePair($, keyToRemove)
    case is Object -> 
        e 
           filterObject ((v, k) -> !((keyToRemove contains (k as String)) or ((v is String) and (keyToRemove contains (v as String))))) 
           mapObject ($$):removePair($,keyToRemove)
    else -> e
  }
---
removePair(payload, keyToRemove)

Output (for input in the question):

{
  "test": [
    {
      "objectName": "test"
    }
  ]
}