Shape.OLEFormat and its position in the excel sheet

I wanted to create a simple macro that simply checked if a check box is checked or not and based on that, hide or show the row.

But there are some catches, I cannot link the chackbox to the cell, otherwise another bigger macro generates an error.

I did researcha bit and found that you can do:

sheets(1).shapes("Checkbox 88").topleftcell.row

to get the row of the shape.

So I tried to implement this to my code:

    Dim sh As Shape    
    For Each sh In Sheets(1).Shapes
        If TypeOf sh.OLEFormat.Object Is CheckBox Then
            If sh.OLEFormat.Object.Value = -4146 Then
                'sh.OLEFormat.Object.TopLeftCell.Row.EntireRow.Hidden = True
                MsgBox "Hi"
            End If
        End If
    Next sh

I know that the:

sh.OLEFormat.Object.TopLeftCell.Row.EntireRow.Hidden = True

is wrong, because if I run the macro as I posted it, the macro returns the msgbox "Hi", because the wrong part is commented.

The strange part for me is that if I do:

    Dim aux As Byte
    Dim sh As Shape
    
    aux = Sheets(1).Shapes("Checkbox 88").OLEFormat.Object.TopLeftCell.Row
    'checkbox 88 is one of the checkboxes/shapes in the excel document
    MsgBox aux

it works to get the row...

I am thinking that the error has to do with the OLEFormat.object or something, but my google researches came empty handed.

I would think about ditching checkboxes and replacing them with hyperlinks styled to act like checkboxes. This allows sorting, copying and pasting, etc with no chance of "drift" where checkboxes can become detached from their assigned row.

Eg: code for creating and supporting links (in a regular module)

'add some hyperlink "checkboxes" to cell in a range
Sub CreateCheckboxes()
    Dim i As Long
    For i = 1 To 20
        AddCheckBox ActiveSheet.Cells(i, "B")
    Next i
End Sub

'Add a "checkbox" to a cell and do some formatting
Sub AddCheckBox(c As Range)
    With c
        .Hyperlinks.Delete
        .Worksheet.Hyperlinks.Add anchor:=c, Address:="#LinkTarget()", _
                                  TextToDisplay:=UncheckedValue
        .Font.Name = "Wingdings"  'this font has the "checkbox" characters 
        .Font.Size = 12           'remove the default blue+underline formatting
        .Font.Underline = False
        .Font.Color = vbBlack
        .HorizontalAlignment = xlCenter
    End With
End Sub

'This serves as a "dummy" destination for the hyperlinks
'  Just returns the clicked-on cell, so the selection doesn't jump around
Function LinkTarget() As Range
    Set LinkTarget = Selection
End Function

'Text for a "checked" cell
'Spaces are just to expand the "clickable" area of the hyperlink
Function CheckedValue() As String
    CheckedValue = " " & Chr(120) & " "
End Function
'Text for an "unchecked" cell
Function UncheckedValue() As String
    UncheckedValue = " " & Chr(111) & " "
End Function
'Is a cell "checked"
Function IsChecked(c As Range) As Boolean
    IsChecked = (c.Value = CheckedValue)
End Function

Switch link appearance on click (worksheet code module):

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
    Dim c As Range
    Set c = Target.Range
    
    If c.Column = 2 Then    'if (eg) you need to take some specific action based on where the cell is
        Debug.Print c.Address
        Select Case c.Text  'Toggle cell text
            'You can add code below if some specific action 
            '  to be taken when a checkbox is checked/unchecked.
            'This code just toggles the checkbox appearance
            Case CheckedValue: c.Value = UncheckedValue
            Case UncheckedValue: c.Value = CheckedValue
            Case Else: c.Value = UncheckedValue
        End Select
    End If
End Sub