Functional coverage problem using with instead of iff

module tb;
  logic [1:0] a,b;
  logic sel;
  
  covergroup c;
    option.per_instance = 1;
    coverpoint a{
      wildcard bins a_={2'b??} with (sel);
    }
    coverpoint b{
      wildcard bins b_={2'b??} iff (!sel);
    }
  endgroup
    
    c ci;
    
    initial begin
      ci=new();
      repeat(10) begin
        a=$random;
        b=$random;
        sel=$random;
        $display("%d %d %d",a,b,sel);
        ci.sample();
        #1;
      end
    end
    
endmodule

Coverage is not showing when I am using with, but when I use iff in place of with, it's working. What I am doing wrong?

When I run your code on VCS, I get a helpful compile error:

Error-[FCIWCS] Invalid 'with' clause specification
tb.sv, 8
tb, "a_cp"
  The 'with' clause specified on the coverpoint bin does not have any impact 
  and is invalid; it should contain at least one occurence of the 'item' 
  keyword.
  Please remove or correct the clause and compile

Replacing sel with item works:

coverpoint a{
  wildcard bins a_={2'b??} with (item);
}

However, running the code on Cadence's simulator still produces a compile error:

> with expression is not supported for wildcard bin.

Using iff is more portable.

The with clause in a bin expression gets evaluated once at the point when the covergroup gets constructed and determines the set of which bin values that get created as part of a coverpoint. Since sel is uninitialized at that point, there are no bins created for coverpoint a.

The iff clause in a bin expression gets evaluated each time the covergroup gets sampled and is effectively a sample enable expression. It has no effect on the selection of bin values created.

Most likely using iff matches your intended behavior.