How to convert hash to array without the use of intermediate variable?

How to convert hash to to array temporarily without using intermediate variable

For example in the following code "@arr" variable is an array storing the converted hash.

my %scientists = (
	"Newton"   => "Isaac",
	"Einstein" => "Albert",
	"Darwin"   => "Charles",
);

my @arr = %scientists;
print $_ . " " foreach @arr; # "Newton Isaac Darwin Charles Einstein Albert"

I am not trying to accomplish anything specific here. Just want to know if its possible to convert hash to an array wihtout intermediate variable

print ref(\@arr); # print array

similarly is there a something that can replace "<syntax>" so that the following is possible

print ref(<syntax>%scientists%<sytax>) # should print array.

In list context, %hash results in a key-value pairs of scalars.

For example, %scientists results in the six scalars "Newton", "Isaac", "Einstein", "Albert", "Darwin", "Charles", although the order can vary.

This applies on the right-hand side of my @arr =.

my @arr = %scientists;

And it also applies for the list of a foreach loop.

print $_ . " " for %scientists;

Most of the time, however, one would use keys( %scientists ) instead of just %scientists.

say "$_ $scientists{ $_ }" for keys( %scientists );

For the question at the bottom, you could use

say ref( [ %scientists ] );

[ ... ] is roughly equivalent to do { my @anon = ...; \@anon }.

In other words, it still creates an array, but the array is anonymous.

The wording of the question seems inconsistent -- it is asking about an array, seemingly wanting a list in fact, but the discussion doesn't clearly support that either. Perhaps it is a quest of how to "serialize" or stringify a hash, without creating variables. Here are some options

To print a hash I often use

say "$_ => $h{$_}" for keys %h; 

or, so that it is always in the same order,

say "$_ => $h{$_}" for sort keys %h; 

This approach can be used to build a list or a string of the key-value pairs. For example

map { "$_ => $h{$_}" } keys %h;   # list of key-value strings 

what can be further manipulated. (With a hashref it's keys %$hr and $h->{$_} instead.)

Also, "dumper" libraries unpack data structures for us

use Data::Dump qw(pp);

my $fmt_str = pp \%h;  # formatted string. for formatted print use 'dd'

The package Data::Dump need be installed. A core module, which should come installed with Perl, is Data::Dumper (function Dumper returns a formatted string). There are yet others .

What do you want the conversion to do?

If you want only the keys you can do

my @lastnames = keys %scientists;

If you want only the values you can do

my @firstnames = values %scientists;

If you want them intermingled as key/value pairs just do

my @names = %scientists;

The thing to remember is that since hashes are unordered, you don't know what order you will get back.

Your wording is a bit confusing (Array vs List), but I think what you really want is to convert a %Hash variable to a List in order to dump it, without intermediate @array variable.

Here a quick demo in the debugger:

> print ref(@arr); # print array

  DB<7> use Data::Dumper

  DB<8> print Dumper \%h
$VAR1 = {
          'Einstein' => 'Albert',
          'Darwin' => 'Charles',
          'Newton' => 'Isaac'
        };

  DB<9>

NB: Data::Dumper is core, i.e. available with every Perl version.

I personally prefer Data::Dump, which needs to be installed from CPAN.