perl add line into text file

I am writing a script to append text file by adding some text under specific string in the file after tab spacing. Help needed to add new line and tab spacing after matched string "apple" in below case.

Example File:

apple
<tab_spacing>original text1
orange
<tab_spacing>original text2

Expected output:

apple
<tab_spacing>testing
<tab_spacing>original text1
orange
<tab_spacing>original text2

What i have tried:

use strict;
use warnings;
my $config="filename.txt";
open (CONFIG,"+<$config") or die "Fail to open config file $config\n";
	while (<CONFIG>) {
		chop;
		if (($_ =~ /^$apple$/)){
			print CONFIG "\n";
			print CONFIG "testing\n";
		}
}
      close CONFIG;

We cannot simply "add" text to a middle of a file as attempted. A file is a sequence of bytes and one cannot add or remove them (except at the end) but only change them. So if we start writing to a middle of a file then we are changing the bytes there, so overwriting what follows that place. Instead, we have to copy the rest of the text and write it back following the "addition," or to copy the file adding text in the process.

Yet another way is to read the whole file into a string and run a regex on it to change it, then write out the new string. Assuming that the file isn't too large for that

perl -0777 -pe's{apple\n\K(\t)}{Added text\n$1}g' in.txt

The -0777 switch makes it read the whole file into a string ("slurp" it), available in $_, to which the regex is bound by default. That \K, which is a lookbehind, drops previous matches so they are not consumed out of the string and we don't have to (capture and) put them back. With the /g modifier it keeps going through the whole string, to find and change all occurrences of the pattern.

This prints the changed file to screen, what can be saved in a new file by redirecting it

perl -0777 -pe'...' in.txt > out.txt

Or, one can change the input file "in place" with -i

perl -0777 -i.bak -pe'...' in.txt 

The .bak makes it save the original with .bak extension. See switches in perlrun.

Another way is to use a lookahead for what follows (the tab) so that we don't have to capture and put it back

perl -0777 -pe's{apple\n\K(?=\t)}{Added text\n}g' in.txt

All of these produce the desired change.

Note on that tab ("tab_spacing")

The regex above assumes a tab character at the beginning of the line following the line with apple. When we say "tab" we mean one (tab) character.

But there are many reasons why there may in fact not be a tab character, even if it looks just like there is one. An example: all tabs may be automatically replaced by spaces by an editor.

So it may be safer to use \s+ (multiple spaces) instead of \t in the regex

s{apple\n\K(\s+)}{Added text\n$1}g

or

s{apple\n\K(?=\s+)}{Added text\n}g

If this is to be done inside of an existing larger Perl program (and not as a command-line program, "one-liner," as above), one way

use Path::Tiny;  # path(), constructor

my $file_content = path($file)->slurp;  # read the file into a string

# Now use a regex; all discussion above applies
$file_content =~ s{apple\n\K(?=\t)}{Added text\n}g;

# Print out $file_content, to be redirected etc. Or write to a file
path($new_file)->spew($file_content);

I use the library Path::Tiny to "slurp" the file into a string and spew to write $file_content to a new file. That need be installed as it is not in a "core" (doesn't usually come installed with Perl), and if that is a problem for some strange reason here is an idiom-of-sorts for it without any libraries

my $file_content = do { 
    local $/;
    open my $fh, '<', $file or die "Can't open $file: $!";
    <$fh>;
};

or even

my $file_content = do { local (@ARGV, $/) = $file; <> };

(see this post for some explanation and references)

Some pretty weird stuff in your code, to be honest:

• Reading from and writing to a file at the same time is hard. Your code, for example, would just write all over the existing data in the file
• Using a bareword filehandle (CONFIG) instead of a lexical variable and two-arg open() instead of the three-arg version (open my $config_fh, '+<', $config') makes me think you're using some pretty old Perl tutorials
• Using chop() instead of chomp() makes me think you're using some ancient Perl tutorials
• You seem to have an extra $ in your regex - ^$apple$ should probably be ^apple$

Also, Tie::File has been included with Perl's standard library for over twenty years and would make this task far easier.

#!/usr/bin/perl

use strict;
use warnings;

use Tie::File;

tie my @file, 'Tie::File', 'filename.txt' or die $!;

for (0 .. $#file) {
  if ($file[$_] eq 'apple') {
    splice @file, $_ + 1, 0, "\ttesting\n";
  }
}

It's not entirely clear what you mean by "tab spacing", but you might be looking for:

perl -pE 'm/^(\t*)/; say "testing" if $a; $a = /apple/' filename.txt

I suspect you actually want \s instead of \t, but YMMV. Basically, on each line of input, you match the leading whitespace and then print a line with that whitespace and the string 'testing' if the previous line matched.

To write it verbosely:

#!/usr/bin/env perl

use 5.12.0;
use strict;
use warnings;
my $n = 'filename.txt';

open my $f, '<', $n, or die "$n: $!\n";
while(<$f>){
        m/^(\t*)/;    # possibly \s is preferred over \t
        say "testing" if $a;
        $a = /apple/;
        print;
}