What is the quickest way to draw a random sample from SAS dataset?

I have a very large SAS data set (sas7bdat, 136 billion rows, 636 columns). I just need a random sample of 10k rows to test code - does not need to be statistically representative.

I am running code which I guess works but takes so long to run.

libname input "/some_linux_path/";

proc surveyselect data=input.large_data
	out=random_sample
	method=srs
	sampsize=10000;
run;

Is there a quicker way? Perhaps just take the first 10k observations?

The easiest way to take the first 10000 observations is through a data step:

data sequential_sample;
    set have(obs=10000);
run;

If you want to efficiently sample 10000 random values, use direct access with the point= dataset option. We'll draw a random number from 1 to n, where n is the number of observations in the dataset. The random number corresponds to a row on the dataset. This method uses random sampling with replacement, which is unlikely to be a problem for a sufficiently small sample proportion.

data random_sample;
    do i = 1 to 10000;
        rand = ceil(rand('uniform', 0, n) );
        set have point=rand nobs=n;
        output;
    end;

    stop;
    drop i;
run;

Just be sure i, n, and rand are not in your dataset. If they are, use other variable names.

This code is a little strange because n is used before we define it. This is a unique feature of the nobs= option. SAS knows the number of observations in the dataset and loads it into n before the first row is read in.

Now let's say you don't want to have the possibility of a repeat draw when randomly sampling from a dataset. We can modify the above code to continue to choose a random number until we get one that we have not seen yet.

/* Set sample size */
%let s = 10000;

data random_sample;
    array rand_nums[&s.] _TEMPORARY_;

    do i = 1 to &s.;

        /* Initialize a flag that keeps a loop going until it's 0 */
        flag_repeat_draw = 1;

        /* Keep generating a random number until we find one that we 
           haven't seen yet */
        do while(flag_repeat_draw);
            rand = ceil(rand('uniform', 0, n) ); 

            /* If we haven't seen this number, save it and set the
               repeat draw flag to 0 to force the loop to end */
            if(rand NOT IN rand_nums) then do;
                rand_nums[i]     = rand;
                flag_repeat_draw = 0;
            end;
        end;

        set have point=rand nobs=n;
        output;
    end;

    stop;
    drop i;
run;

Note that this method becomes increasingly inefficient the closer the sample size is to the actual number of observations.