Method error in Julia when using Parameters.jl

I want to define variables as below, but does not when I add the line time::Vector{Float32}=[a:step:b]
using Parameters

@with_kw mutable struct variables
 InetrpolationDegree::Int = 1
        a::Float32 =0.0
        b::Float32 =15.0
        N::Int = 100
     step::Float32 = (b-a)/N
        time::Vector{Float32}=[a:step:b]
end

t=variables(N=100).time;
Δt=variables(N=100).step;
s=variables(N=100).InetrpolationDegree

I got this this error

> MethodError: Cannot convert an object of type StepRangeLen{Float64,
> Base.TwicePrecision{Float64}, Base.TwicePrecision{Float64}, Int64} to
> an object of type Float32

You should be aware that the constructed object through a:step:b is subtype of the AbstractRange AbstractType. So wrapping it within brackets [a:step:b] won't make an object of type Vector{Float32}! Thus, you should declare the correct type within braces. Since the returned object is a Vector, which in the element is an object <:AbstractRange (read it: subtype of AbstractRange), we can say:
time::Vector{<:AbstractRange}=[a:step:b]

@with_kw mutable struct variables
  InetrpolationDegree::Int = 1
  a::Float32 =0.0
  b::Float32 =15.0
  N::Int = 100
  step::Float32 = (b-a)/N
  time::Vector{<:AbstractRange}=[a:step:b]
end;

t=variables(N=100).time;
Δt=variables(N=100).step;
s=variables(N=100).InetrpolationDegree # returns 1

Additional Note

Keep in mind that you can also use Base.@kwdef rather than @with_kw.

Your problem appears to be that you are wrapping your range-object in brackets, []. That turns it into a Vector of ranges, which may not be what you actually want. Changing the field signature to

time::Vector{<:AbstractRange}=[a:step:b]

removes the error but has some unfortunate side effects. Firstly, you now have a vector of ranges, instead of just a plain range. Secondly, the field is now abstractly typed, which is bad for performance.

I suggest these two alternatives instead:

Fix the type signature and remove the brackets:

@with_kw mutable struct Variables
    InterpolationDegree::Int = 1  # this field was mis-spelled
    a::Float32 = 0.0f0  # using literal float syntax (not strictly necessary)
    b::Float32 = 15.0f0
    N::Int = 100
    step::Float32 = (b-a)/N
    Time::StepRangeLen{Float32,Float64,Float64,Int64} = (a:step:b)
end

Or, collect the vector and fix the signature:

@with_kw mutable struct Variables
    InterpolationDegree::Int = 1
    a::Float32 = 0.0f0
    b::Float32 = 15.0f0
    N::Int = 100
    step::Float32 = (b-a)/N
    Time::Vector{Float32} = collect(a:step:b)
end

I prefer the first alternative, if possible, since it uses a lightweight range, instead of a Vector which wastes memory, especially for long time-intervals.

Two more remarks:

1. By convention, type names should be capitalized: Variables, not variables.
2. Are you sure that your struct needs to be mutable? Immutable structs have better performance, and can be safer from accidental mutation.