Hide activecell column across tabs using VBA

I am trying to hide the activecell column across first 4 tabs.

I select highlight first 4 tabs and select cell A1 then use below code:

ActiveCell.EntireColumn.Hidden = True

This hides column A in first tab, but not tab 2, 3, 4.

It has to be the selected cell and not Range("A1").EntireColumn.Hidden = True, because the cell can be any active cell I am trying to hide using an offset function.

You could store the location of the active cell, then cycle through each worksheet and use that location to base your column hiding..

Sub tested()

    Dim cell_address As String
    Dim wsName, ws, c As Range
    
    cell_address = ActiveCell.Address
    
    wsName = Array("Sheet1", "Sheet2", "Sheet3", "Sheet4")
    
    For Each ws In wsName
        Sheets(ws).Range(cell_address).EntireColumn.Hidden = True
    Next

End Sub

Hide the Same Column in Different Worksheets

• There is no way to combine (select) cells from multiple worksheets at the same time so you need to loop through the worksheets and hide each column separately, one after the other.

Usage

<!-- language: lang-vb -->

Sub HideCellColumnsTEST()
    
    Dim wsIDs(): wsIDs = Array(1, 2, 3, 4)
 
    Dim ws As Worksheet: Set ws = ActiveSheet
    
    Dim cell As Range: Set cell = ws.Range("A1")
    'or:
    'Set cell = ActiveCell
    'Set cell = ActiveCell.Offset(, 3) '...etc.

    HideCellColumns cell, wsIDs

End Sub

The Method

<!-- language: lang-vb -->

Sub HideCellColumns(ByVal cell As Range, ByVal wsIDs As Variant)
    
    Dim CellAddress As String: CellAddress = cell.Address
    Dim wb As Workbook: Set wb = cell.Worksheet.Parent

    Dim ws As Worksheet, wsID
    
    For Each wsID In wsIDs
        On Error Resume Next
            Set ws = wb.Worksheets(wsID)
        On Error GoTo 0
        If Not ws Is Nothing Then ' worksheet exists
            ws.Range(CellAddress).EntireColumn.Hidden = True
            Set ws = Nothing ' reset for the next iteration
        'Else ' worksheet doesn't exist; do nothing!?
        End If
    Next wsID

End Sub