Paste specific worksheet range into email body

I'm quite new VBA programming and I need help with something that I need at my work.
I have a sheet that I created to reduce the time spent by my team workers on their job during the day and just to give more information, we use this sheet to fill all the information regarding critical issues that the team manage into war rooms.
The team is responsible to send announcements for the company when a critial issue is hapening and as the old process were generating a lack of standardization in these announcements, I decided to create this sheet with a custom layout for e-mails.
And to prevent workers to edit this layout, I protected the worksheets and created buttons with macros to generate these announcements, but as spected from a newbie person, it's not working properly as spected.

Below is a screenshot from this worksheet where the announcement is generated. The cells starts at B6 and ends at L27. The worksheet identification is "Planilha5" and what I need is: When the worker click over the SEND button present into the worksheet, a new message into Microsoft Outlook 365 is invoked and filled with the defined information into the VBA script and the worksheet defined range must be pasted into the body of the mail message.

Announcement screenshot

And this is the VBA script that I'm trying to modify to be used:

Sub EnviarAbertura()
Dim Outlook As Object, Novo_Email As Object, Email_Body As String, b1 As Variant

b1 = Planilha5.Range("B6:L27")

Set Outlook = CreateObject("Outlook.application")

    Email_Body = b1
    
    Set Novo_Email = Outlook.CreateItem(0)
    Corpo = Planilha5.Range("B6:L27").Copy
    
    With Novo_Email
    .SentOnBehalfOfName = "centraldecomandotd@natura.net"
    .Subject = Planilha5.Range("G4")
    .Body = Email_Body
    .Display
    
    End With
    
End Sub

When I comment the lines 'b1 = Planilha5.Range("B6:L27")'; 'Email_Body = b1'; '.Body = Email_Body', the script works properly without the body filled.

VBA Script working properly

I have pasted manually the worksheet range into a screenshot below to show you guys what I'm specting to do with the VBA Script.

Expected results

Please, could someone help me with this VBA script?

There are two main ways of setting the message body based on the Excel data:

1. Build the HTML markup based on the worksheet content. That is basically what Ron described on the Mail Range/Selection in the body of the mail page where you can find the following sample code:

   Function RangetoHTML(rng As Range)
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook
   
    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
   
    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
   
    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
   
    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
   
    'Close TempWB
    TempWB.Close savechanges:=False
   
    'Delete the htm file we used in this function
    Kill TempFile
   
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
    End Function
   

   Note, after getting the HTML markup you need to use the HTMLBody property, not the plain text Body.

2. You can copy the required range in Excel by using the Range.Copy method and then paste directly to the message body by using the Word editor, see the WordEditor property of the Inspector class. The property returns the Microsoft Word Document Object Model of the message being displayed. See Chapter 17: Working with Item Bodies for more information.