Import Various Tables with Different Formats from PDF into Excel

I am trying to import multiple PDF tables into Excel using Power Query but the tables appear on different pages with 3 different formats of the table. Sometimes some PDF's in the directory do not have the tables at all

I plan to import from multiple PDF tables with various formats and the values I need to extract are shown in the attached image in red.

The results that I need are shown in the excel file format. The results in blue are from the first table format, the results in yellow are from the second table format and the results in green are from the third table format. I just color coded it for the sake of explaining the my problem

Overall, I plan to read through a folder that has about 700 pdf files with these tables but these tables do not appear on specific pages and some of the PDFs may have multiple other tables that are not relevant.
I want the Query to be able to skip all those irrelevant tables and pick the table formats that I specified.

Thank you in advance.

I tried using Power Query but I am still a newbie in the application

Based on sample data file posted elsewhere, if actual data format was identical to that, this would work for you to combine all of those PDF files from a specified directory. It does not actually skip any tables in a file since your sample data did not include any data like that to test out, but should be modifiable if necessary by putting some filters before the #"Added Custom" step to remove the non-desirable tables

let 

group= (filename)=>
//open each file and pull out all the tables
let Source = Pdf.Tables(File.Contents(filename), [Implementation="1.3"]),
List = List.Union(List.Transform(Source[Data], each Table.ColumnNames(_))), 
#"Expanded Data" = Table.ExpandTableColumn(Source, "Data", List,List),
#"Filtered Rows" = Table.SelectRows(#"Expanded Data", each Text.StartsWith([Name], "Table")),
#"Grouped Rows" = Table.Group(#"Filtered Rows", {"Name"}, {{"data", each _, type table}}),
#"Added Custom" = Table.AddColumn(#"Grouped Rows", "Custom", each split([data]))
in #"Added Custom",

//process each table
split= (variable)=>  let
#"Filtered Rows1" = Table.SelectRows(variable,  each ([Column1] <> "" and [Column1]<>null and [Column1]<>"Final" and [Column2] <> "" and [Column2]<>null)),
#"Promoted Headers" = Table.PromoteHeaders(#"Filtered Rows1", [PromoteAllScalars=true]),
#"Removed Columns" = Table.RemoveColumns(#"Promoted Headers",List.FirstN(Table.ColumnNames(#"Promoted Headers"),3)), 
Names=List.RemoveNulls(List.Transform(Table.ColumnNames(#"Removed Columns"), each  if Text.Contains(_,"Volume") or Text.Contains(_,"Unit") then _ else null)),
#"Removed Other Columns" = Table.SelectColumns(#"Removed Columns",Names),
FirstName=List.First(Table.ColumnNames(#"Removed Other Columns")),
#"Unpivoted Other Columns" = Table.UnpivotOtherColumns(#"Removed Other Columns",{FirstName} , "Attribute", "Value"),
#"Renamed Columns" = Table.RenameColumns(#"Unpivoted Other Columns",{{FirstName, "Category"}}),
Transform = Table.TransformColumns(#"Renamed Columns",{{"Attribute",each Text.BeforeDelimiter(_,"_"), type text}}),
//Dates
RepeatCount=Table.RowCount(#"Removed Columns"),
Dates = Record.ToList(variable{1}),
b = List.RemoveNulls(List.Transform(Dates, each try if Text.Contains (_,"(") and not Text.Contains (_,"Table")  then Text.BeforeDelimiter(_, "(")  else null otherwise null)),
a={List.Repeat(b,RepeatCount + 2)},
//Distance
#"Promoted Headers5" = Table.PromoteHeaders(variable, [PromoteAllScalars=true]),
Distance = List.Repeat(List.RemoveNulls(List.Transform(Table.ColumnNames(#"Promoted Headers5"), each try if Text.Contains(_,"Distance") then Number.From(Text.Select(_,{"0".."9"})) else null otherwise null)),List.Count(Names)-1),DistanceTable= Table.FromList(Distance, Splitter.SplitByNothing(), {"Value"}, null, ExtraValues.Error),
#"Added Custom3" = Table.AddColumn(DistanceTable, "Category", each "Distance"),
//Total
#"Filtered Rows5" = Table.SelectRows(variable, each ([Column1] = "Final")){0},
r=Record.ToList(#"Filtered Rows5"),
s=List.PositionOf(r,"Final"),
rr=List.Transform(r, each if _="" then null else _),
t=List.RemoveNulls(List.RemoveFirstN(rr,s+1)),
TotalTable= Table.FromList(t, Splitter.SplitByNothing(), {"Value"}, null, ExtraValues.Error),
#"Added Custom4" = Table.AddColumn(TotalTable, "Category", each "Final"),
//combine it all
h = Table.FromColumns(Table.ToColumns(Transform&#"Added Custom3"& #"Added Custom4")&a),
#"Removed Columns1" = Table.RemoveColumns(h,{"Column2"}),
#"Changed Type" = Table.TransformColumnTypes(#"Removed Columns1",{{"Column1", type text}, {"Column3", type number}, {"Column4", type date}}),
#"Pivoted Column" = Table.Pivot(#"Changed Type", List.Distinct(#"Changed Type"[Column1]), "Column1", "Column3", List.Sum)
in #"Pivoted Column",

Source2 = Folder.Files("c:\temp\"),
#"Filtered Rows" = Table.SelectRows(Source2, each ([Extension] = ".pdf")),
#"Added Custom" = Table.AddColumn(#"Filtered Rows", "Data", each group([Folder Path]&[Name])),
#"Renamed Columns" = Table.RenameColumns(#"Added Custom",{{"Name", "zName"}}),
#"Expanded Data" = Table.ExpandTableColumn(#"Renamed Columns", "Data",{"Name","Custom"},{"Name","Custom"}),
List = List.Union(List.Transform(#"Expanded Data"[Custom], each Table.ColumnNames(_))), 
#"Expanded Data2" = Table.ExpandTableColumn(#"Expanded Data", "Custom", List,List),
#"Changed Type" = Table.TransformColumnTypes(#"Expanded Data2",{{"Column4", type date}})  
in  #"Changed Type"

EDIT to add error removal

Source2 = Folder.Files("c:\temp\"),
#"Filtered Rows" = Table.SelectRows(Source2, each ([Extension] = ".pdf")),
#"Added Custom" = Table.AddColumn(#"Filtered Rows", "Data", each group([Folder Path]&[Name])),
#"Renamed Columns" = Table.RenameColumns(#"Added Custom",{{"Name", "zName"}}),
#"Expanded Data" = Table.ExpandTableColumn(#"Renamed Columns", "Data",{"Name","Custom"},{"Name","Custom"}),
#"Removed Errors" = Table.RemoveRowsWithErrors(#"Expanded Data", {"Custom"}),
List = List.Union(List.Transform(#"Removed Errors"[Custom], each Table.ColumnNames(_))), 
#"Expanded Data2" = Table.ExpandTableColumn(#"Removed Errors", "Custom", List,List),
#"Changed Type" = Table.TransformColumnTypes(#"Expanded Data2",{{"Column4", type date}})  
in  #"Changed Type"

EDIT final notes

change [Column1]<>"Final" to not Text.Contains([Column1], "Final")


change  each ([Column1] = "Final") to each (Text.Contains([Column1],"Final"))


change s=List.PositionOf(r,"Final") to s=if List.PositionOf(r,"Final") = -1 then List.PositionOf(r,"Pre-Flow Final") else  List.PositionOf(r,"Final")