I cannot execute my bootloader file in qemu emulator

org 0x7c00 

section .text
    mov ah, 0x0e  
    mov si, message  

print_loop:
    lodsb            
    or al, al        
    jz done          
    int 0x10        
    jmp print_loop   

done:
    hlt             

section .data
    message db "Hello, World!", 0 

times 510-($-$$) db 0   
dw 0xaa55 

When I try to execute this code in my qemu emulator, it shows "no bootable device found". How can I fix it?

You may want to check the actual content of the generated boot sector to make sure it complies with the rules. I think that's basically just ensuring the final two bytes are the correct signature.

The reason I bring this up is because I think $-$$ is the wrong thing to use here, if you're using sections. It works out the difference between current location and the start of the section, not the start of the boot sector.

So, with a code section of fifteen bytes and an immediately following data section of fourteen bytes (both roughly what you have), 510 - ($ - $$) in the data section becomes 510 - (29 - 15) = 496. That means you will have:

• 15 bytes of code.
• 14 bytes of data.
• 496 bytes of padding.

That's a total of 525 bytes before you generate the signature so it won't be at the correct location, meaning the boot loader will not recognise the disk as bootable. In this case, offset 1fe will contain two of the 00 bytes from the padding.

The following listing generated by your original code confirms this:

                         org 0x7c00
                         section .text
00000000 B40E                mov ah, 0x0e
00000002 BE[0000]            mov si, message
                         print_loop:
00000005 AC                  lodsb
00000006 08C0                or al, al
00000008 7404                jz done
0000000A CD10                int 0x10
0000000C EBF7                jmp print_loop
                         done:
0000000E F4                  hlt
                         section .data
00000000                 message:
00000000 48656C6C6F2C20      db "Hello, World!", 0
00000008 576F726C642100
0000000E 00<*496>            times 510-($-$$) db 0
000001FE 55AA                dw 0xaa55

You can see that the signature is at offset 1fe but that offset is relative to the start of the data section (because the message is at offset 000 within that section). That means it's not taking into account how much space is used by the code when combining the two sections into a boot sector.

If instead you place it all in one section, the expression should then become 510 - (29 - 0) = 481, giving the correct 510 bytes before the signature:

• 15 bytes of code.
• 14 bytes of data.
• 481 bytes of padding.

This still looks like the signature goes at offset 1fe in the listing but that's the offset within the code (and only) section, with the message at 00f. There's also less padding between the message and the signature:

                         org 0x7c00
                         section .text
00000000 B40E                mov ah, 0x0e
00000002 BE[0000]            mov si, message
                         print_loop:
00000005 AC                  lodsb
00000006 08C0                or al, al
00000008 7404                jz done
0000000A CD10                int 0x10
0000000C EBF7                jmp print_loop
                         done:
0000000E F4                  hlt
0000000F                 message:
0000000F 48656C6C6F2C20      db "Hello, World!", 0
00000016 576F726C642100
0000001D 00<*481>            times 510-($-$$) db 0
000001FE 55AA                dw 0xaa55

And just some minor points on your code.

First, hlt will indeed halt the CPU but the next external interrupt can restart it. Since you probably don't want that to try and execute your message, it may be worthwhile protecting against that with:

done:
    hlt
    jmp done

Second, when BIOS transfers control to your code, there's very little that you should rely on. For example, you should not assume that ds is set to, as you seem to expect it, the same value as cs.

You should explicitly force that to be the case, as well as setting up anything else that's needed such as the stack pointer.