Capture "Enter Key" to initiate command button click in excel vba

I have the following code to use a userform to input username/password. It works great when the command button is click but I want to also capture when the "Enter Key" is hit to initiate the command button click event. It uses a label caption to determine which state it is in, either username or password and does a username validation to make sure it is a proper email address. I am trying to get it to work both ways, by hitting the command button to initiate or by hitting the "Enter Key". Right now I have to hit the "Enter Key' twice to get it to work.

Private Const EMAIL_REGEX As String = "^[a-zA-Z0-9._%+-]+@[a-zA-Z0-9.-]+\.[a-zA-Z]{2,4}$"
Private IsEnteringUsername As Boolean

Private Sub CBUserName_Click()
    Dim regex As Object
    Set regex = CreateObject("VBScript.RegExp")

    regex.Global = True
    regex.IgnoreCase = True
    regex.Pattern = EMAIL_REGEX

    If regex.Test(UsernamePasswordTextBox.Value) Then
        M8Username = UsernamePasswordTextBox.Value
        LbUserPass.Caption = "Please enter your Password"
        CBUserName.Visible = False
        CBPassWord.Visible = True
        UsernamePasswordTextBox.Value = ""
        UsernamePasswordTextBox.PasswordChar = "*"
        UsernamePasswordTextBox.SetFocus
    Else
        MsgBox "Invalid Username!"
        UsernamePasswordTextBox.Value = ""
        UsernamePasswordTextBox.SetFocus
    End If

    Set regex = Nothing
End Sub

Private Sub CBPassWord_Click()
    M8Password = UsernamePasswordTextBox.Value
    LbUserPass.Caption = "Please enter your Username"
    CBUserName.Visible = True
    CBPassWord.Visible = False
    UsernamePasswordTextBox.PasswordChar = ""
    Me.Hide
    GetJobs
End Sub

Private Sub UserForm_Activate()
    UsernamePasswordTextBox.Value = ""
    LbUserPass.Caption = "Please enter your Username"
    UsernamePasswordTextBox.SetFocus
    CBUserName.Visible = True
    CBPassWord.Visible = False
    Me.Left = Application.Left + (0.5 * Application.Width) - (0.5 * Me.Width)
    Me.Top = Application.Top + (0.5 * Application.Height) - (0.5 * Me.Height)
    IsEnteringUsername = True
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = VbQueryClose.vbFormControlMenu Then
        MsgBox "You must enter a valid Username & Password to use this program"
        Cancel = True
    End If
End Sub

Private Sub UserForm_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    Dim regex As Object

    If KeyCode = KeyCodeConstants.vbKeyReturn Then
        Set regex = CreateObject("VBScript.RegExp")
        regex.Global = True
        regex.IgnoreCase = True
        regex.Pattern = EMAIL_REGEX

        If IsEnteringUsername Then
            If regex.Test(UsernamePasswordTextBox.Value) Then
                M8Username = UsernamePasswordTextBox.Value
                LbUserPass.Caption = "Please enter your Password"
                CBUserName.Visible = False
                CBPassWord.Visible = True
                UsernamePasswordTextBox.Value = ""
                UsernamePasswordTextBox.PasswordChar = "*"
                UsernamePasswordTextBox.SetFocus
            Else
                MsgBox "Invalid Username!"
                UsernamePasswordTextBox.Value = ""
                UsernamePasswordTextBox.SetFocus
            End If
        Else
            M8Password = UsernamePasswordTextBox.Value
            LbUserPass.Caption = "Please enter your Username"
            CBUserName.Visible = True
            CBPassWord.Visible = False
            UsernamePasswordTextBox.PasswordChar = ""
        End If

        Set regex = Nothing
    End If
End Sub

New code:

Private Sub UsernamePasswordTextBox_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
   
    If KeyCode = KeyCodeConstants.vbKeyReturn Then
        If LbUserPass.Caption = "Please enter your Username" Then
            Call CBUserName_Click
        Else
            Call CBPassWord_Click
        End If
    End If

End Sub

Userform_KeyDown won't fire if a control has focus. Catch Enter in TextBox_KeyDown instead, the side effect is TextBox losing focus.

Private Sub UsernamePasswordTextBox_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = 13 Then
        Call CBUserName_Click
    End If
End Sub